Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Convex hull

Sample Viewer View Sample on GitHub

Create a convex hull for a given set of points. The convex hull is a polygon with shortest perimeter that encloses a set of points. As a visual analogy, consider a set of points as nails in a board. The convex hull of the points would be like a rubber band stretched around the outermost nails.

Use case

A convex hull can be useful in collision detection. For example, when charting the position of two yacht fleets (with each vessel represented by a point), if their convex hulls have been precomputed, it is efficient to first check if their convex hulls intersect before computing their proximity point-by-point.

How to use the sample

Tap on the map to add points. Click the "Convex hull" button to generate the convex hull of those points. Click the "Reset" button to start over.

How it works

  1. Create an input geometry such as a Multipoint object.
  2. Use GeometryEngine.convexHull(inputGeometry)to create a new Geometry object representing the convex hull of the input points. The returned geometry will either be a Point, Polyline, or Polygon based on the number of input points.

Relevant API

  • Geometry
  • GeometryEngine

Tags

convex hull, geometry, spatial analysis

Sample Code

import QtQuick 2.6
import Esri.ArcGISRuntime 100.9
import QtQuick.Layouts 1.11
import QtQuick.Controls 2.6

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    MapView {
        id: mapView
        anchors.fill: parent

        Map {
            BasemapTopographic {}
        }

        GraphicsOverlay {
            id: graphicsOverlay

            Graphic {
                id: inputsGraphic
                SimpleMarkerSymbol {
                    id: markerSymbol
                    style: Enums.SimpleMarkerSymbolStyleCircle
                    size: 10
                    color: "red"
                }
            }

            Graphic {
                id: convexHullGraphic
            }
        }

        SimpleFillSymbol {
            id: fillSymbol
            style: Enums.SimpleFillSymbolStyleNull
            color: "transparent"
            SimpleLineSymbol {
                id: lineSymbol
                style: Enums.SimpleLineSymbolStyleSolid
                width: 3
                color: "blue"
            }
        }

        MultipointBuilder {
            id: multipointBuilder
            spatialReference: mapView.spatialReference
        }

        onMouseClicked: {
            const clickedPoint = mapView.screenToLocation(mouse.x, mouse.y);
            multipointBuilder.points.addPoint(clickedPoint);
            inputsGraphic.geometry = multipointBuilder.geometry;
        }

        RowLayout {
            anchors {
                left: parent.left
                top: parent.top
            }

            Button {
                Layout.fillWidth: true
                Layout.fillHeight: true
                text: "Convex hull"

                // display the convex hull
                onClicked: {
                    // normalizing the geometry before performing geometric operations
                    const normalizedPoints = GeometryEngine.normalizeCentralMeridian(multipointBuilder.geometry);
                    const convHull = GeometryEngine.convexHull(normalizedPoints);
                    if (convHull.geometryType === Enums.GeometryTypePoint) {
                        convexHullGraphic.symbol = markerSymbol;
                    } else if (convHull.geometryType === Enums.GeometryTypePolyline) {
                        convexHullGraphic.symbol = lineSymbol;
                    } else if (convHull.geometryType === Enums.GeometryTypePolygon) {
                        convexHullGraphic.symbol = fillSymbol;
                    }
                    else {
                        console.warn("Not a valid geometry");
                    }

                    convexHullGraphic.geometry = convHull;
                }
            }

            Button {
                Layout.fillWidth: true
                Layout.fillHeight: true
                text: "Reset"

                onClicked: {
                    multipointBuilder.points.removeAll();
                    inputsGraphic.geometry = null;
                    convexHullGraphic.geometry = null;
                }
            }
        }
    }
}