Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Create and save KML file

Sample Viewer View Sample on GitHub

Construct a KML document and save it as a KMZ file.

Use case

If you need to create and save data on the fly, you can use KML to create points, lines, and polygons and then serializing them as KML nodes in a KML Document. Once complete, you can share the KML data with others that are using a KML reading application, such as ArcGIS Earth.

How to use the sample

Application opens to a view of the Southwestern United States. Click on the "Save KMZ file" button to save the active KML document as a .kmz file on your system.

How it works

  1. Create a Point, Polyline, and Polygon.
  2. Create a Graphic for each and add it to the GraphicsOverlay
  3. Create a KmlGeometry object using the Geometry from the point, line, and polygon.
  4. Create a KmlPlacemark for each kml geometry.
  5. Set a KmlStyle for each placemark.
  6. Add all three kml placemarks to the KmlDocument.
  7. Save the kml document to a file using the saveAs function.

Relevant API

  • KmlDocument
  • KmlGeometry
  • KmlIcon
  • KmlIconStyle
  • KmlLineStyle
  • KmlNode.saveAs
  • KmlPlacemark
  • KmlPolygonStyle
  • KmlStyle

Tags

Keyhole, KML, KMZ, OGC

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.12
import Qt.labs.platform 1.1 as Dialogs
import Esri.ArcGISRuntime 100.9
import Esri.ArcGISExtras 1.1

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    MapView {
        id: mapView
        anchors.fill: parent

        Map {
            BasemapDarkGrayCanvasVector {}

            // add a KML Layer
            KmlLayer {
                KmlDataset {
                    id: kmlDataset
                    KmlDocument {
                        id: kmlDocument
                        name: qsTr("KML Sample Document")
                        onSaveStatusChanged: {
                            if (saveStatus === Enums.TaskStatusErrored) {
                                console.log(`Error: ${error.message} - ${error.additionalMessage}`);
                            }
                            else if (saveStatus === Enums.TaskStatusCompleted) {
                                saveCompleteDialog.open();
                            }
                        }
                    }
                }
            }

            // set initial extent
            ViewpointExtent {
                Envelope {
                    id: myViewpoint
                    xMin: -123.0
                    yMin: 33.5
                    xMax: -101.0
                    yMax: 42.0
                    spatialReference: SpatialReference { wkid: 4326 }
                }
            }
        }

    }

    Button {
        anchors{
            left: parent.left
            top: parent.top
            margins: 3
        }
        text: qsTr("Save kmz file")

        onClicked: {
            fileDialog.open();
        }
    }

    PolygonBuilder {
        id: polygonBuilder
        spatialReference: SpatialReference { wkid: 4326 }
    }

    PolylineBuilder {
        id: polylineBuilder
        spatialReference: SpatialReference { wkid: 4326 }
    }

    Point {
        id: point
        x: -117.195800
        y: 34.056295
        spatialReference: SpatialReference { wkid: 4326 }
    }

    BusyIndicator {
        id: busy
        anchors.centerIn: parent
        visible: kmlDocument.saveStatus === Enums.TaskStatusInProgress
    }

    Dialogs.FileDialog {
        id: fileDialog
        defaultSuffix: "kmz"
        fileMode: Dialogs.FileDialog.SaveFile
        nameFilters: ["Kml files (*.kmz *.kml)"]
        onAccepted: {
            // Write the KML document to the chosen path.
            kmlDocument.saveAs(currentFile);
            close();
        }

        onRejected: {
            close();
        }
    }

    Dialog {
        id: saveCompleteDialog
        anchors.centerIn: parent
        modal: true
        standardButtons: Dialog.Ok
        Text {
            id:textLabel
            anchors.centerIn: parent
            text: qsTr("Item saved.")
        }
    }

    KmlStyle {
        id: kmlStyleWithPointStyle
        KmlIconStyle {
            KmlIcon {
                url: "https://static.arcgis.com/images/Symbols/Shapes/BlueStarLargeB.png"
            }
            scale: 1
        }
    }

    KmlStyle {
        id: kmlStyleWithLineStyle
        KmlLineStyle {
            color: "red"
            width: 2
        }
    }

    KmlStyle {
        id: kmlStyleWithPolygonStyle
        KmlPolygonStyle {
            color: "yellow"
        }
    }

    Component.onCompleted: {
        createPolygon();
        createPolyline();
        createPoint();
    }

    function createPoint() {
        addToKmlDocument(point, kmlStyleWithPointStyle);
    }

    function createPolygon() {
        polygonBuilder.addPointXY(-109.048, 40.998);
        polygonBuilder.addPointXY(-102.047, 40.998);
        polygonBuilder.addPointXY(-102.037, 36.989);
        polygonBuilder.addPointXY(-109.048, 36.998);
        addToKmlDocument(polygonBuilder.geometry, kmlStyleWithPolygonStyle);
    }

    function createPolyline() {
        polylineBuilder.addPointXY(-119.992, 41.989);
        polylineBuilder.addPointXY(-119.994, 38.994);
        polylineBuilder.addPointXY(-114.620, 35.0);
        addToKmlDocument(polylineBuilder.geometry, kmlStyleWithLineStyle);
    }

    function addToKmlDocument(geometry, kmlStyle) {
        const kmlGeometry = ArcGISRuntimeEnvironment.createObject("KmlGeometry", {
                                                                      geometry: geometry,
                                                                      altitudeMode: Enums.KmlAltitudeModeClampToGround
                                                                  });
        const kmlPlacemark = ArcGISRuntimeEnvironment.createObject("KmlPlacemark");
        kmlPlacemark.geometriesListModel.append(kmlGeometry);
        kmlPlacemark.style = kmlStyle;
        kmlDocument.childNodesListModel.append(kmlPlacemark);
    }
}