Create feature collection layer (Portal item)

Sample Viewer View Sample on GitHub

Create a feature collection layer from a portal item.

Use case

Feature collection layers are often used to hold features with mixed geometry or unstructured data. You can display feature collections stored in a Portal, which are often used for showing content from a CSV or map notes.

How to use the sample

The feature collection is loaded from the Portal item when the sample starts.

How it works

Create a Portal.
Create the PortalItem, referring to the portal and an item ID.
Verify that the item represents a feature collection.
Create a FeatureCollection from the item.
Create a FeatureCollectionLayer, referring to the feature collection.
Add the feature collection layer to the map's OperationalLayers collection.

Relevant API

FeatureCollection
FeatureCollectionLayer
Portal
PortalItem

About the data

The sample uses a sample layer depicting world populations.

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.9

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    MapView {
        id: mapView
        anchors.fill: parent

        PortalItem {
            id: portalItem
            itemId: "32798dfad17942858d5eef82ee802f0b"
            Component.onCompleted: load();
            onLoadStatusChanged: {
                if (loadStatus !== Enums.LoadStatusLoaded) {
                    return;
                }

                // if the portal item is a feature collection, add the feature collection to the map's operational layers
                if (type === Enums.PortalItemTypeFeatureCollection) {
                    const featureCollection = ArcGISRuntimeEnvironment.createObject("FeatureCollection", {item: portalItem});
                    const featureCollectionLayer = ArcGISRuntimeEnvironment.createObject("FeatureCollectionLayer", {featureCollection: featureCollection});
                    map.operationalLayers.append(featureCollectionLayer);
                } else {
                    console.warn("Portal item with ID '" + itemId + "' is not a feature collection.")
                }
            }
        }

        Map {
            id: map
            BasemapOceans {}
        }
    }
}