Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Display drawing status

Sample Viewer View Sample on GitHub

Get the draw status of your map view or scene view to know when all layers in the map or scene have finished drawing.

Use case

You may want to display a loading indicator while layers are loading.

How it works

  1. Create a MapView and connect to the onDrawStatusChanged signal.
  2. Use drawStatus on the to determine draw status.

Relevant API

  • Map
  • drawStatus
  • MapView.onDrawStatusChanged
  • MapView

Tags

draw, loading, map, render

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import QtGraphicalEffects 1.0
import Esri.ArcGISRuntime 100.9
import Esri.ArcGISExtras 1.1

Rectangle {
    clip: true
    width: 800
    height: 600

    

    // create MapView
    MapView {
        anchors.fill: parent

        // create map using topographic basemap
        Map {
            BasemapTopographic {}

            // create FeatureLayer using a service URL
            FeatureLayer {
                ServiceFeatureTable {
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/DamageAssessment/FeatureServer/0"
                }
            }

            // set initial viewpoint
            ViewpointExtent {
                Envelope {
                    xMin: -13639984
                    yMin: 4537387
                    xMax: -13606734
                    yMax: 4558866
                    spatialReference: SpatialReference { wkid: 3857 }
                }
            }
        }

        // make Drawing Window visible if map is drawing. Not visible if drawing completed
        onDrawStatusChanged: {
            drawStatus === Enums.DrawStatusInProgress ? mapDrawingWindow.visible = true : mapDrawingWindow.visible = false;
        }
    }

    Rectangle {
        id: mapDrawingWindow
        anchors.fill: parent
        color: "transparent"

        RadialGradient {
            anchors.fill: parent
            opacity: 0.15
            gradient: Gradient {
                GradientStop { position: 0.0; color: "lightgrey" }
                GradientStop { position: 0.7; color: "black" }
            }
        }

        // pop up to show if MapView is drawing
        Rectangle {
            anchors.centerIn: parent
            width: 100
            height: 100
            radius: 3
            opacity: 0.85
            color: "#E0E0E0"
            border.color: "black"

            Column {
                anchors.centerIn: parent
                topPadding: 5
                spacing: 5

                BusyIndicator {
                    anchors.horizontalCenter: parent.horizontalCenter
                    height: 60
                    running: true
                }

                Text {
                    anchors.horizontalCenter: parent.horizontalCenter
                    font {
                        weight: Font.Black
                        pixelSize: 12
                    }
                    height: 20
                    horizontalAlignment: Text.AlignHCenter
                    text: "Drawing..."
                }
            }
        }
    }
}