Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Display KML network links

Sample Viewer View Sample on GitHub

Display a file with a KML network link, including displaying any network link control messages at launch.

Use case

KML files can reference other KML files on the network and support automatically refreshing content. For example, survey workers will benefit from KML data shown on their devices automatically refreshing to show the most up-to-date state. Additionally, discovering KML files linked to the data they are currently viewing provides additional information to make better decisions in the field.

How to use the sample

The sample will load the KML file automatically. The data shown should refresh automatically every few seconds. Pan and zoom to explore the map.

How it works

In general, no special code is needed to support showing KML/KMZ files with network links. KML supports specifying a message to show the user when loading a network link. Apps can optionally listen to the KmlDataset.kmlNetworkLinkMessageReceived signal to show any messages from KML network link controls.

  1. Create a KmlDataset from a KML source which has network links.
  2. Create a KmlLayer with the dataset and add the layer as an operational layer.
  3. To listen for network messages, connect to the kmlNetworkLinkMessageReceived signal of the dataset.

Relevant API

  • KmlDataset
  • KmlLayer
  • KmlNetworkLink
  • kmlNetworkLinkMessageReceived

About the data

This map shows the current air traffic in parts of Europe with heading, altitude, and ground speed. Additionally, noise levels from ground monitoring stations are shown.

Tags

Keyhole, KML, KMZ, Network Link, Network Link Control, OGC

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import QtQuick.Layouts 1.3
import QtQuick.Window 2.3
import Esri.ArcGISRuntime 100.9

Rectangle {
    id: rootRectangle

    
    property string currentKmlNetworkMessage: "";

    clip: true
    width: 800
    height: 600

    SceneView {
        id: sceneView
        anchors.fill: parent
        Scene {
            id: scene
            BasemapImagery {}
            // Center the viewpoint over continental Europe.
            ViewpointCenter {
                Point {
                    x: 8.150526
                    y: 50.472421
                    spatialReference: Factory.SpatialReference.createWgs84()
                }
                targetScale: 20000000
            }
            // The layer that will render our KML data.
            KmlLayer {
                // This is a KML resource that references other KML resources over a network.
                dataset:  KmlDataset {
                    url: "https://www.arcgis.com/sharing/rest/content/items/600748d4464442288f6db8a4ba27dc95/data"

                    onKmlNetworkLinkMessageReceived: {
                        currentKmlNetworkMessage = message;
                    }
                }
            }
        }

        MessageButton {
            visible: currentKmlNetworkMessage. length > 0
            anchors {
                bottom: sceneView.attributionTop
                horizontalCenter: parent.horizontalCenter
                margins: 10
            }
            onClicked: {
                messageDialog.open();
            }
        }
    }

    Dialog {
        id: messageDialog
        modal: true
        x: Math.round(parent.width - width) / 2
        y: Math.round(parent.height - height) / 2
        width: parent.width * 0.75
        standardButtons: Dialog.Ok
        title: "KML layer message"
        property alias text : textLabel.text
        Text {
            width: parent.width
            id: textLabel
            text: currentKmlNetworkMessage
            wrapMode: Text.WordWrap
        }
        onAccepted: {
            currentKmlNetworkMessage = ""; // Clear the message
        }
        onRejected: onAccepted()
    }
}
import QtQuick 2.6
import QtQuick.Controls 2.2

Item {
    id: messageButton
    signal clicked()

    Rectangle {
        anchors.fill: messageContents
        radius: 4

        border {
            color: "darkgray"
            width: 1
        }

        MouseArea {
            anchors.fill: parent
            onClicked: messageButton.clicked()
        }
    }

    Row {
        id: messageContents
        leftPadding: 5
        rightPadding: leftPadding
        spacing: 5
        anchors {
            horizontalCenter: messageButton.horizontalCenter
            bottom: messageButton.bottom
        }

        Image {
            anchors.verticalCenter: parent.verticalCenter
            id: messageImage
            width: 32
            height: 32
            source: "qrc:/Samples/Layers/DisplayKmlNetworkLinks/iOS8_TabBar_Email90.png"
            anchors.margins: 5

            SequentialAnimation on opacity {
                running: messageContents.visible
                loops: Animation.Infinite

                PropertyAnimation { to: 1; duration: 1000; easing.type: Easing.InOutQuad }
                PropertyAnimation { to: 0; duration: 1000; easing.type: Easing.InOutQuad }
            }
        }

        Text{
            id: messageText
            anchors {
                verticalCenter: messageImage.verticalCenter
                margins: 5
            }

            text: "Message Received"
            color: "#2f2f2f"
            font.pixelSize: 13
        }
    }
}