Determine if a layer is currently being viewed.
Use case
The view status includes information on the loading state of layers and whether layers are visible at a given scale. You might change how a layer is displayed in a layer list to communicate whether it is being viewed in the map. For example, you could show a loading spinner next to its name when the view status is Loading, grey out the name when NotVisible or OutOfScale, show the name normally when Active, or with a warning or error icon when the status is Warning or Error.
How to use the sample
Tap the Load layer button to add a feature layer to the map. The current view status of the layer will display on the map. Zoom in and out of the map and note the layer disappears when the map is scaled outside of its min and max scale range. Control the layer's visibility with the Hide layer button. If you disconnect your device from the network and pan around the map, a warning will display. Reconnect to the network to remove the warning. The layer's current view status will update accordingly as you carry out these actions.
How it works
- Create a
Mapwith some operational layers. - Set the map on a
MapView. - Connect to the
layerViewStateChangedsignal from the map view. - Display the
LayerViewStatusflag for theFeatureLayer.
Relevant API
- Enums.LayerViewStatus
- LayerViewState
- Map
- MapView
- MapView.layerViewStateChanged
About the data
The Satellite (MODIS) Thermal Hotspots and Fire Activity layer presents detectable thermal activity from MODIS satellites for the last 48 hours. MODIS Global Fires is a product of NASA’s Earth Observing System Data and Information System (EOSDIS), part of NASA's Earth Science Data. EOSDIS integrates remote sensing and GIS technologies to deliver global MODIS hotspot/fire locations to natural resource managers and other stakeholders around the World.
Additional information
The following are members of the LayerViewStatus enum:
Enums.LayerViewStatusActive: The layer in the view is active.Enums.LayerViewStatusNotVisible: The layer in the view is not visible.Enums.LayerViewStatusOutOfScale: The layer in the view is out of scale. A status ofEnums.LayerViewStatusOutOfScaleindicates that the view is zoomed outside of the scale range of the layer. If the view is zoomed too far in (e.g. to a street level), it is beyond the max scale defined for the layer. If the view has zoomed too far out (e.g. to global scale), it is beyond the min scale defined for the layer.Enums.LayerViewStatusLoading: The layer in the view is loading. Once loading has completed, the layer will be available for display in the view. If there was a problem loading the layer, the status will be set to ERROR.Enums.LayerViewStatusError: The layer in the view has an unrecoverable error. When the status isEnums.LayerViewStatusError, the layer cannot be rendered in the view. For example, it may have failed to load, be an unsupported layer type, or contain invalid data.Enums.LayerViewStatusWarning: The layer in the view has a non-breaking problem with its display, such as incomplete information (eg. by requesting more features than the max feature count of a service) or a network request failure.
If your device supports airplane mode, you can toggle this on and pan around the map to see layers display the WARNING status when they cannot online fetch data. Toggle airplane mode back off to see the warning disappear.
Tags
layer, load, map, status, view, visibility
Sample Code
// [WriteFile Name=DisplayLayerViewDrawState, Category=Maps]
// [Legal]
// Copyright 2020 Esri.
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]
import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import Esri.ArcGISRuntime
import Esri.ArcGISRuntime.Toolkit
Rectangle {
id: rootRectangle
clip: true
width: 800
height: 600
readonly property string portalItemId: "b8f4033069f141729ffb298b7418b653"
property var statusStringList: []
property var warningMessage: ""
MapView {
id: mapView
anchors.fill: parent
Component.onCompleted: {
// Set the focus on MapView to initially enable keyboard navigation
forceActiveFocus();
}
Map {
Basemap {
initStyle: Enums.BasemapStyleArcGISTopographic
}
}
FeatureLayer {
id: featureLayer
serviceLayerIdAsInt: 0
minScale: 400000000
maxScale: 400000000 / 10
visible: loadLayerButton.text === qsTr("Hide Layer") ? true : false
PortalItem {
id: portalItem
itemId: portalItemId
}
// once loaded set the viewpoint
onLoadStatusChanged: {
if (loadStatus !== Enums.LoadStatusLoaded)
return;
mapView.map.operationalLayers.append(featureLayer);
mapView.setViewpointCenter(viewPoint);
mapView.setViewpointScale(40000000.0);
}
}
Dialog {
id: warningDialog
anchors.centerIn: parent
standardButtons: Dialog.Ok
visible: warningMessage !== ""
Text {
id: warningText
text: warningMessage;
}
}
onLayerViewStateChanged: (layer, layerViewState) => {
// only update list if the layer is the feature layer.
if (layer.name !== featureLayer.name)
return;
// clear list for new view state(s).
statusStringList = [];
if (layerViewState.statusFlags & Enums.LayerViewStatusActive) {
statusStringList.push("Active");
}
if (layerViewState.statusFlags & Enums.LayerViewStatusError) {
statusStringList.push("Error");
}
if (layerViewState.statusFlags & Enums.LayerViewStatusLoading) {
statusStringList.push("Loading");
}
if (layerViewState.statusFlags & Enums.LayerViewStatusNotVisible) {
statusStringList.push("NotVisible");
}
if (layerViewState.statusFlags & Enums.LayerViewStatusOutOfScale) {
statusStringList.push("OutOfScale");
}
if (layerViewState.statusFlags & Enums.LayerViewStatusWarning) {
statusStringList.push("Warning");
warningMessage = qsTr("Warning message: %1".arg(layerViewState.error.message));
}
layerViewStatusRepeater.model = statusStringList;
}
Rectangle {
id: controlRect
anchors {
bottom: loadLayerButton.top
horizontalCenter: parent.horizontalCenter
margins: 5
}
width: childrenRect.width
height: childrenRect.height
color: "#1976D2"
radius: 3
MouseArea {
width: controlLayout.childrenRect.width
height: controlLayout.childrenRect.height
onClicked: mouse => mouse.accepted = true;
onWheel: wheel => wheel.accepted = true;
}
ColumnLayout{
id: controlLayout
Text {
id: textHeader
text: qsTr("Current view status:")
color: "white"
Layout.alignment: Qt.AlignHCenter
}
Column {
id: column
Layout.alignment: Qt.AlignHCenter
Repeater {
id: layerViewStatusRepeater
Item {
width: childrenRect.width
height: childrenRect.height
Text {
text: modelData
color: "white"
}
}
}
}
}
}
Button {
id: loadLayerButton
anchors {
bottom: mapView.attributionTop
horizontalCenter: parent.horizontalCenter
margins: 5
}
text: qsTr("Load Layer")
enabled: featureLayer.loadStatus !== Enums.LoadStatusLoading ? true : false
clip: true
onClicked: {
if (text === qsTr("Load Layer")) {
// load a feature layer from a portal item
featureLayer.load();
text = qsTr("Hide Layer");
}
else if (text === qsTr("Hide Layer"))
text = qsTr("Show Layer");
else if (text === qsTr("Show Layer"))
text = qsTr("Hide Layer");
}
}
}
Point {
id: viewPoint
x: -11000000
y: 4500000
spatialReference: Factory.SpatialReference.createWebMercator();
}
}