Edit KML ground overlay

View inC++QMLView on GitHubSample viewer app

Edit the values of a KML ground overlay.

screenshot

Use case

KML ground overlays are used for showing aerial imagery, symbology, or other images draped over a scene. Changing the geometry, rotation, and other attributes of a ground overlay after it has been loaded allows for live editing. For example, editing the geometry and opacity of a historical image draped over present day satellite imagery makes it possible to view change over time.

How to use the sample

Use the slider to adjust the opacity of the ground overlay.

How it works

  1. Create an Envelope defining the geometry of the overlay.
  2. Create a KmlIcon using a Url linking to an image.
  3. Create a KmlGroundOverlay using the envelope and icon.
  4. Set the value ofKmlGroundOverlay.rotation.
  5. Create a KmlDataset using the ground overlay.
  6. Create a KmlLayer using the dataset.
  7. Add the KML layer to the scene.
  8. Listen for changes to the opacity slider and change the KmlGroundOverlay.color value appropriately.

Relevant API

  • KmlDataset
  • KmlGroundOverlay
  • KmlIcon
  • KmlLayer

About the data

The image used in this sample is an aerial view of the campus of the University of Oregon. This imagery was taken in 1944 by the U.S. Army Corps of Engineers. It is publicly available as Online Aerial Imagery hosted by Oregon University Library. It is also available as a Portal item on ArcGIS Online as University of Oregon Campus Aerial Imagery - 1944.

Tags

imagery, keyhole, KML, KMZ, OGC

Sample Code

EditKmlGroundOverlay.qml
Use dark colors for code blocksCopy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
// [WriteFile Name=EditKmlGroundOverlay, Category=EditData]
// [Legal]
// Copyright 2019 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import Esri.ArcGISRuntime
import Esri.ArcGISExtras

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property url dataPath: {
        Qt.platform.os === "ios" ?
                    System.writableLocationUrl(System.StandardPathsDocumentsLocation) + "/ArcGIS/Runtime/Data/raster/" :
                    System.writableLocationUrl(System.StandardPathsHomeLocation) + "/ArcGIS/Runtime/Data/raster/"
    }

    SceneView {
        id: sceneView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on SceneView to initially enable keyboard navigation
            forceActiveFocus();
        }

        Scene {
            Basemap {
                initStyle: Enums.BasemapStyleArcGISImageryStandard
            }

            // Create a KML Layer
            KmlLayer {
                id: kmlLayer
                // Create a KML Dataset
                KmlDataset {
                    // Create a Ground Overlay by assigning an icon and geometry
                    KmlGroundOverlay {
                        id: groundOverlay
                        rotation: -3.046024799346924
                        KmlIcon {
                            url: dataPath + "1944.jpg"
                        }
                        Envelope {
                            id: env
                            xMin: -123.066227926904
                            yMin: 44.04736963555683
                            xMax: -123.0796942287304
                            yMax: 44.03878298600624
                            SpatialReference {
                                wkid: 4326
                            }
                        }
                    }
                }

                // set viewpoint to the ground overlay
                onLoadStatusChanged: {
                    if (loadStatus !== Enums.LoadStatusLoaded)
                        return;

                    const camera = ArcGISRuntimeEnvironment.createObject("Camera", {
                                                                             location: env.center,
                                                                             distance: 1250,
                                                                             heading: 45,
                                                                             pitch: 60,
                                                                             roll: 0
                                                                         });

                    sceneView.setViewpointCamera(camera);
                }
            }
        }
    }

    Rectangle {
        anchors.fill: slider
        radius: 5
    }

    Slider {
        id: slider
        anchors {
            left: parent.left
            top: parent.top
            margins: 10
        }
        from: 0
        to: 1
        value: 1
        stepSize: 0.1
        onValueChanged: {
            // modify the overlay's color/alpha value
            groundOverlay.color = Qt.rgba(0, 0, 0, value);
        }
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.