Feature collection layer (query)

View inC++QMLView on GitHubSample viewer app

Create a feature collection layer to show a query result from a service feature table.

screenshot

Use case

Consider a national wireless telecommunications company who wants to improve connectivity within areas of poor coverage. Their cell towers, cell tower radii and state boundaries data are held within service feature tables, which can be queried for states that don't meet a certain threshold of coverage. The query result can be used to create and display a single feature collection layer for analysis of areas requiring improved coverage.

How to use the sample

When launched, this sample displays a map with point features as a feature collection layer. Pan and zoom to explore the map.

How it works

  1. Perform a query using the queryFeatures() method on a ServiceFeatureTable.
  2. Instantiate a FeatureCollectionTable with the result of the query.
  3. Create a FeatureCollection and add the feature collection table to it.
  4. Create a FeatureCollectionLayer from the feature collection.
  5. Add the feature collection layer to the map's operationalLayers list.

Relevant API

  • FeatureCollection
  • FeatureCollectionLayer
  • FeatureCollectionTable
  • FeatureLayer
  • FeatureQueryResult
  • FeatureTable
  • QueryParameters
  • ServiceFeatureTable

About the data

This application utilizes data from the wildfire feature service. It loads at full extent with features indicating wildfire response point features across the world.

Tags

layer, query, search, table

Sample Code

FeatureCollectionLayerQuery.qml
Use dark colors for code blocksCopy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
// [WriteFile Name=FeatureCollectionLayerQuery, Category=Layers]
// [Legal]
// Copyright 2017 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import Esri.ArcGISRuntime

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property bool busy: featureTable.queryFeaturesStatus === Enums.TaskStatusInProgress

    MapView {
        id: mapView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
        }

        Map {
            id: map
            Basemap {
                initStyle: Enums.BasemapStyleArcGISOceans
            }
        }
    }

    ServiceFeatureTable {
        id: featureTable
        url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/Wildfire/FeatureServer/0"

        onQueryFeaturesStatusChanged: {
            if (queryFeaturesStatus !== Enums.TaskStatusCompleted)
                return;

            const featureCollectionTable = ArcGISRuntimeEnvironment.createObject("FeatureCollectionTable", {featureSet: queryFeaturesResult});

            const featureCollection = ArcGISRuntimeEnvironment.createObject("FeatureCollection");
            featureCollection.tables.append(featureCollectionTable);

            featureCollectionLayer.featureCollection = featureCollection;
        }

        Component.onCompleted: {
            queryFeatures(queryParams);
        }
    }

    QueryParameters {
        id: queryParams
        whereClause: "1=1"
    }

    FeatureCollectionLayer {
        id: featureCollectionLayer

        onFeatureCollectionChanged: {
            map.operationalLayers.append(featureCollectionLayer);
        }
    }

    BusyIndicator {
        anchors.centerIn: parent
        visible: busy
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.