Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Line of sight (location)

Sample Viewer View Sample on GitHub

This sample demonstrates how to perform a line of sight analysis between two points in a SceneView.

Use case

A line of sight analysis can be used to assess whether a view is obstructed between an observer and a target. Obstructing features could either be natural, like topography, or man-made, like buildings. Consider an events planning company wanting to commemorate a national event by lighting sequential beacons across hill summits or roof tops. To guarantee a successful event, ensuring an unobstructed line of sight between neighboring beacons would allow each beacon to be activated as intended.

How to use the sample

The sample loads with a preset observer and target location, linked by a colored line. A red segment on the line means the view between observer and target is obstructed, whereas green means the view is unobstructed.

Click to turn on the mouse move event listener, then move the mouse to update the target location in real time. Click again to lock the target location.

How it works

  1. Create an AnalysisOverlay and add it to the scene view.
  2. Create a LocationLineOfSight with initial observer and target locations and add it to the analysis overlay.
  3. Capture mouse movement with the mousePositionChanged signal. Turn the screen point into a scene point with sceneView.screenToLocation(screenPoint).
  4. Update the target location with lineOfSight.setTargetLocation(scenePoint).

Relevant API

  • AnalysisOverlay
  • LocationLineOfSight
  • SceneView
  • Surface
  • ArcGISTiledElevationSource

Tags

3D, line of sight, visibility, visibility analysis

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISExtras 1.1
import Esri.ArcGISRuntime 100.9

Rectangle {
    clip: true
    width: 800
    height: 600

    
    property bool calculating: false

    SceneView {
        id: sceneView
        anchors.fill: parent
        focus: true

        Scene {
            id: scene
            BasemapTopographic {}

            Surface {
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }

            onLoadStatusChanged: {
                if (loadStatus === Enums.LoadStatusLoaded) {
                    setInitialViewpoint();
                }
            }
        }

        // Add an Analysis Overlay
        AnalysisOverlay {
            id: analysisOverlay

            // Declare a LineOfSight and set initial observer and target locations
            LocationLineOfSight {
                id: locationLineOfSight
                visible: true
                observerLocation: Point {
                    x: -73.06958032962375
                    y: -49.253112971555446
                    z: 2000
                    spatialReference: Factory.SpatialReference.createWgs84()
                }
                targetLocation: Point {
                    x: -73.079266999709162
                    y: -49.300457676730559
                    z: 1312
                    spatialReference: Factory.SpatialReference.createWgs84()
                }

                // Configure the LoS color and width
                Component.onCompleted: {
                    LineOfSight.setVisibleColor("cyan");
                    LineOfSight.setObstructedColor("magenta");
                    LineOfSight.setLineWidth(2);
                }
            }
        }

        // Update the target location as you tap the map
        onMouseClicked: locationLineOfSight.targetLocation = sceneView.screenToBaseSurface(mouse.x, mouse.y);
        onMousePressedAndHeld: calculating = true;
        onMouseReleased: calculating = false;
        onMousePositionChanged: {
            if (!calculating)
                return;

            locationLineOfSight.targetLocation = sceneView.screenToBaseSurface(mouse.x, mouse.y);
        }
    }

    function setInitialViewpoint() {
        // Set a viewpoint
        const point = ArcGISRuntimeEnvironment.createObject("Point", {
                                                                x: -73.0815,
                                                                y: -49.3272,
                                                                z: 4059,
                                                                spatialReference: Factory.SpatialReference.createWgs84()
                                                            });

        const camera = ArcGISRuntimeEnvironment.createObject("Camera", {
                                                                 location: point,
                                                                 heading: 11,
                                                                 pitch: 62,
                                                                 roll: 0
                                                             });

        sceneView.setViewpointCamera(camera);
    }
}