Project

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
// [WriteFile Name=ProjectGeometry, Category=Geometry]
// [Legal]
// Copyright 2018 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import Esri.ArcGISRuntime
import Esri.ArcGISRuntime.Toolkit

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    MapView {
        id: mapView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
        }

        Map {
            Basemap {
                initStyle: Enums.BasemapStyleArcGISTopographic
            }

            // Set initial viewpoint to Minneapolis
            ViewpointExtent {
                Envelope {
                    xMin: -10995912.335747
                    yMin: 5267868.874421
                    xMax: -9880363.974046
                    yMax: 5960699.183877
                    spatialReference: SpatialReference { wkid: 3857 }
                }
            }
        }

        // Declare a callout
        Callout {
            id: callout
            calloutData: parent.calloutData
            accessoryButtonVisible: false
            autoAdjustWidth: true
            maxWidth: 350
            leaderPosition: Callout.LeaderPosition.Automatic
        }

        // create a graphics to show the input location
        GraphicsOverlay {

            // create a red marker symbol for the input point
            Graphic {
                id: inputGraphic

                SimpleMarkerSymbol {
                    color: "red"
                    size: 5
                    style: Enums.SimpleMarkerSymbolStyleCircle
                }
            }
        }

        // handle mouseClicked signal
        onMouseClicked: mouse => {
            // get the mouse click as a point
            const originalPoint = mouse.mapPoint;

            // show the clicked location on the map with a graphic
            inputGraphic.geometry = originalPoint;

            // create the output SpatialReference by specifying a well known ID (WKID)
            const spatialReference = ArcGISRuntimeEnvironment.createObject("SpatialReference", {
                                                                               wkid: 4326
                                                                           });

            // project the web mercator point to WGS84
            const projectedPoint = GeometryEngine.project(originalPoint, spatialReference);

            // update callout data
            calloutData.title = "Coordinates"
            calloutData.location = originalPoint;
            const ox = originalPoint.x.toFixed(5)
            const oy = originalPoint.y.toFixed(5);
            const px = projectedPoint.x.toFixed(5);
            const py = projectedPoint.y.toFixed(5);
            calloutData.detail = "Original: %1, %2\nProjected: %3, %4".arg(ox).arg(oy).arg(px).arg(py);

            // show the callout
            callout.showCallout();
        }
    }
}