Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Raster function (service)

Sample Viewer View Sample on GitHub

Load a raster from a service, then apply a function to it.

Use case

Raster functions allow processing operations that can be applied to one or more rasters on the fly. Functions can be applied to rasters that come from a service. A land survey agency may apply hillshade and aspect functions to rasters with elevation data in order to better determine the topography of a landscape and to make further planning decisions.

How to use the sample

The raster function is applied automatically when the sample starts and the result is displayed.

How it works

  1. Create the ImageServiceRaster referring to the image server URL.
  2. Create the RasterFunction from a JSON string.
  3. Set the raster argument with rasterFunction.setRaster(rasterName, imageServiceRaster).
  4. Create a new Raster referring to the raster function.
  5. Create a RasterLayer to visualize the computed raster.
  6. Display the raster.

Relevant API

  • ImageServiceRaster
  • Raster
  • RasterFunction
  • RasterFunctionArguments
  • RasterLayer

About the data

The sample applies a hillshade function to a raster produced from the National Land Cover Database, NLCDLandCover2001. You can learn more about the hillshade function in the ArcMap documentation.

Additional information

The raster function computation happens locally on the client device.

Tags

function, layer, raster, raster function, service

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.9
import Esri.ArcGISExtras 1.1

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600
    
    readonly property string dataPath: System.userHomePath + "/ArcGIS/Runtime/Data/raster/"

    MapView {
        anchors.fill: parent
        id: mapView

        Map {
            // create a basemap from a tiled layer and add to the map
            BasemapStreets {}

            // create and add a raster layer to the map
            RasterLayer {
                // create the raster layer from an image service raster
                ImageServiceRaster {
                    id: imageServiceRaster
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/NLCDLandCover2001/ImageServer"

                    // zoom to the extent of the raster once it's loaded
                    onLoadStatusChanged: {
                        if (loadStatus === Enums.LoadStatusLoaded) {
                            const scale = 50000000;
                            mapView.setViewpointCenterAndScale(imageServiceRaster.serviceInfo.fullExtent.center, scale);
                        }
                    }
                }
            }
        }
    }

    // Create a button to apply the raster function
    Rectangle {
        id: button
        property bool pressed: false

        anchors {
            right: parent.right
            bottom: parent.bottom
            rightMargin: 20
            bottomMargin: 40
        }

        width: 45
        height: width
        color: pressed ? "#959595" : "#D6D6D6"
        radius: 100
        border {
            color: "#585858"
            width: 1
        }

        Image {
            anchors {
                centerIn: parent
            }
            width: 26
            height: width
            source: "qrc:/Samples/Layers/RasterFunctionService/RasterImageAnalysisHillshade.png"
        }

        MouseArea {
            anchors.fill: parent
            onPressed: button.pressed = true
            onReleased: button.pressed = false
            onClicked: applyRasterFunction()
        }
    }

    function applyRasterFunction() {
        if (!hillShadeJson.exists) {
            console.log("JSON file for the raster function does not exist");
            return;
        }

        //! [ImageServiceRaster Apply a raster function]
        // create raster function
        const rasterFunction = ArcGISRuntimeEnvironment.createObject("RasterFunction", {path: dataPath + "/hillshade_simplified.json"});
        // get the arguments
        const rasterFunctionArguments = rasterFunction.arguments;
        // set the raster
        rasterFunctionArguments.setRaster("raster", imageServiceRaster);

        // create the raster from the raster function
        const raster = ArcGISRuntimeEnvironment.createObject("Raster", { rasterFunction: rasterFunction });

        // create raster layer from raster
        const rasterLayer = ArcGISRuntimeEnvironment.createObject("RasterLayer", { raster: raster });
        //! [ImageServiceRaster Apply a raster function]

        // add raster to map
        mapView.map.operationalLayers.clear();
        //! [ImageServiceRaster qml add raster operational]
        mapView.map.operationalLayers.append(rasterLayer);
        //! [ImageServiceRaster qml add raster operational]
    }

    FileInfo {
        id: hillShadeJson
        url: dataPath + "/hillshade_simplified.json"
    }
}