Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Raster rendering rule

Sample Viewer View Sample on GitHub

Display a raster on a map and apply different rendering rules to that raster.

Use case

Raster images whose individual pixels represent elevation values can be rendered in a number of different ways, including representation of slope, aspect, hillshade, and shaded relief. Applying these different rendering rules to the same raster allows for a powerful visual analysis of the data. For example, a geologist could interrogate the raster image to map subtle geological features on a landscape, which may become apparent only through comparing the raster when rendered using several different rules.

How to use the sample

Run the sample and use the drop-down menu at the top to select a rendering rule.

How it works

When the sample starts, an ImageServiceRaster is created and added to a RasterLayer. The RasterLayer is then added to the map as an operational layer. Connect to the loadStatusChanged signal for the ImageServiceRaster. Once the ImageServiceRaster is loaded, the RenderingRuleInfos are fetched. Iterate over each item in the RenderingRuleInfos to get the rendering rule name and populate a data model using the names. This becomes the model for the combo box. When an item from the combo is selected and apply is pressed, the RenderingRuleInfo for the selected index is fetched from the service info. A RenderingRule object is created using the RenderingRuleInfo and applied to a newly created ImageServiceRaster. The ImageServiceRaster is then added to the RasterLayer.

  1. Create an ImageServiceRaster using a URL to an online image service.
  2. After loading the raster, use imageServiceRaster.serviceInfo.renderingRuleInfos to get a list of RenderingRuleInfo supported by the service.
  3. Choose a rendering rule info to apply and use it to create a RenderingRule.
  4. Create a new ImageServiceRaster using the same URL.
  5. Apply the rendering rule to the new raster by setting imageServiceRaster.renderingRule = renderingRule.
  6. Create a RasterLayer from the raster for display.

Relevant API

  • ImageServiceRaster
  • RasterLayer
  • RenderingRule

About the data

This raster image service contains 9 LAS files covering Charlotte, North Carolina's downtown area. The lidar data was collected in 2007. Four Raster Rules are available for selection: None, RFTAspectColor, RFTHillshade, and RFTShadedReliefElevationColorRamp.

Additional information

Image service rasters of any type can have rendering rules applied to them; they need not necessarily be elevation rasters. See the list of raster function objects and syntax for rendering rules in the ArcGIS REST API documentation.

Tags

raster, rendering rules, visualization

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import QtQuick.Layouts 1.3
import Esri.ArcGISRuntime 100.9
import Esri.ArcGISExtras 1.1

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    property var renderingRuleNames: []
    readonly property url imageServiceUrl: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/CharlotteLAS/ImageServer"

    MapView {
        anchors.fill: parent
        id: mapView

        Map {
            id: map
            // create a basemap from a tiled layer and add to the map
            BasemapStreets {}

            //! [RasterRenderingRule qml ImageServiceRaster]
            // create and add a raster layer to the map
            RasterLayer {
                // create the raster layer from an image service raster
                ImageServiceRaster {
                    id: imageServiceRaster
                    url: imageServiceUrl

                    // zoom to the extent of the raster once it's loaded
                    onLoadStatusChanged: {
                        if (loadStatus === Enums.LoadStatusLoaded) {
                            mapView.setViewpointGeometry(imageServiceRaster.serviceInfo.fullExtent);

                            const renderingRuleInfos = imageServiceRaster.serviceInfo.renderingRuleInfos;
                            const names = [];
                            for (let i = 0; i < renderingRuleInfos.length; i++) {
                                names.push(renderingRuleInfos[i].name);
                            }
                            renderingRuleNames = names;
                        }
                    }
                }
            }
            //! [RasterRenderingRule qml ImageServiceRaster]
        }

        Rectangle {
            anchors {
                left: parent.left
                top: parent.top
                margins: 5
            }
            height: childrenRect.height
            width: childrenRect.width
            color: "silver"
            radius: 5

            GridLayout {
                columns: 2

                Label {
                    Layout.margins: 10
                    Layout.columnSpan: 2
                    Layout.alignment: Qt.AlignHCenter
                    text: "Apply a Rendering Rule"
                    font.pixelSize: 16
                }

                ComboBox {
                    id: renderingRulesCombo
                    property int modelWidth: 0
                    Layout.minimumWidth: modelWidth + leftPadding + rightPadding + indicator.width
                    model: renderingRuleNames
                    onModelChanged: {
                        for (let i = 0; i < model.length; ++i) {
                            metrics.text = model[i];
                            modelWidth = Math.max(modelWidth, metrics.width);
                        }
                    }
                    TextMetrics {
                        id: metrics
                        font: renderingRulesCombo.font
                    }
                }

                Button {
                    id: applyButton
                    Layout.margins: 10
                    text: "Apply"
                    onClicked: {
                        applyRenderingRule(renderingRulesCombo.currentIndex);
                    }
                }
            }
        }
    }

    function applyRenderingRule(index) {
        //! [ImageServiceRaster Create a rendering rule]
        // get the rendering rule info at the selected index
        const renderingRuleInfo = imageServiceRaster.serviceInfo.renderingRuleInfos[index];
        // create a rendering rule object using the rendering rule info
        const renderingRule = ArcGISRuntimeEnvironment.createObject("RenderingRule", {renderingRuleInfo: renderingRuleInfo});
        // create a new image service raster
        const newImageServiceRaster = ArcGISRuntimeEnvironment.createObject("ImageServiceRaster", {url: imageServiceUrl});
        // apply the rendering rule
        newImageServiceRaster.renderingRule = renderingRule;
        // create a raster layer using the image service raster
        const rasterLayer = ArcGISRuntimeEnvironment.createObject("RasterLayer", {raster: newImageServiceRaster});
        //! [ImageServiceRaster Create a rendering rule]
        // add the raster layer to the map
        map.operationalLayers.append(rasterLayer);
    }
}