Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Style WMS layer

Sample Viewer View Sample on GitHub

Change the style of a Web Map Service (WMS) layer.

Use case

Layers hosted on WMS may have different pre-set styles available to apply to them. Swapping between these styles can help during visual examination of the data. For example, increasing the contrast of satellite images can help in identifying urban and agricultural areas within forested areas.

How to use the sample

Select one of the styles and the map will update the display with the selected style.

How it works

  1. Create a WmsLayer specifying the URL of the service and the layer names you want.
  2. When the layer is done loading, get its list of style strings using wmsLayer.sublayers[0].sublayerInfo.styles.
  3. Set one of the styles using wmsLayer.sublayers[0].currentStyle = styleString.

Relevant API

  • WmsLayer
  • WmsSublayer
  • WmsSublayerInfo

About the data

This sample uses a public service managed by the State of Minnesota and provides composite imagery for the state and the surrounding areas.

Tags

imagery, styles, visualization, WMS

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.9

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600
    
    property var sublayer: null
    property var styles

    MapView {
        id: mapView
        anchors.fill: parent

        Map {
            BasemapImagery {}

            WmsLayer {
                id: wmsLayer
                url: "https://imageserver.gisdata.mn.gov/cgi-bin/mncomp?SERVICE=WMS&VERSION=1.3.0&REQUEST=GetCapabilities"
                layerNames: ["mncomp"]

                onLoadStatusChanged: {
                    if (loadStatus !== Enums.LoadStatusLoaded)
                        return;

                    // zoom to the layer
                    mapView.setViewpointGeometry(fullExtent);

                    // get the subLayer
                    sublayer = sublayers[0];

                    // get the styles
                    styles = sublayer.sublayerInfo.styles;
                }
            }
        }
    }

    Rectangle {
        anchors {
            fill: controlColumn
            margins: -5
        }
        color: "lightgray"
        radius: 5
        opacity: 0.75
    }

    ButtonGroup {
        buttons: controlColumn.children
    }

    Column {
        id: controlColumn
        anchors {
            left: parent.left
            top: parent.top
            margins: 10
        }
        spacing: 5

        RadioButton {
            text: "Default"
            checked: true
            onCheckedChanged: {
                if (checked) {
                    if (!sublayer)
                        return;

                    // set the style string on the sublayer
                    sublayer.currentStyle = styles[0];
                }
            }
        }

        RadioButton {
            text: "Contrast Stretch"
            onCheckedChanged: {
                if (checked) {
                    if (!sublayer)
                        return;

                    // set the style string on the sublayer
                    sublayer.currentStyle = styles[1];
                }
            }
        }
    }
}