WMTS layer

View inC++QMLView on GitHubSample viewer app

Display a layer from a Web Map Tile Service.

screenshot

Use case

WMTS services can have several layers. You can use the ArcGIS Maps SDK for Qt to explore the layers available from a service. This would commonly be used to enable a browsing experience where users can choose which layers they want to display at run time.

How to use the sample

The layer will be displayed automatically. Pan and zoom to explore the map.

How it works

To display a WMTS layer directly from a URL:

  1. Create a WmtsService object using the URL of the WMTS service.
  2. Create a WmtsLayer object with the ID of the layer to display.

To explore layers from a WMTS service:

  1. Create a WmtsService object using the URL of the WMTS service.
  2. After loading the WMTS service, get the list of WmtsLayerInfo objects from the service info of the WMTS service.
  3. Use one of the layer infos to create the WMTS layer.
  4. Create a basemap with the WMTS layer and set it to the map.

Relevant API

  • WmtsLayer
  • WmtsLayerInfo
  • WmtsService
  • WmtsServiceInfo

About the data

The map visualizes world time zones.

Tags

layer, OGC, raster, tiled, web map tile service

Sample Code

WMTS_Layer.qml
Use dark colors for code blocksCopy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
// [WriteFile Name=WMTS_Layer, Category=Layers]
// [Legal]
// Copyright 2017 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import Esri.ArcGISRuntime

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property url wmtsServiceUrl: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/WorldTimeZones/MapServer/WMTS"
    property WmtsService service;

    MapView {
        id: mapView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
            createWmtsLayer();
        }
    }

    function createWmtsLayer() {
        // create the service
        service = ArcGISRuntimeEnvironment.createObject("WmtsService", { url: wmtsServiceUrl });

        // connect to loadStatusChanged signal of the service
        service.loadStatusChanged.connect(()=> {
            if (service.loadStatus === Enums.LoadStatusLoaded) {
                // get the layer info list
                const serviceInfo = service.serviceInfo;
                const layerInfos = serviceInfo.layerInfos;
                // get the first layer id from the list
                const layerId = layerInfos[0].wmtsLayerId;
                // create WMTS layer
                const wmtsLayer = ArcGISRuntimeEnvironment.createObject("WmtsLayer", {
                                                                            url: wmtsServiceUrl,
                                                                            layerId: layerId
                                                                        });
                // create a basemap from the layer
                const basemap = ArcGISRuntimeEnvironment.createObject("Basemap");
                basemap.baseLayers.append(wmtsLayer);
                // create a map
                const map = ArcGISRuntimeEnvironment.createObject("Map", {
                                                                      basemap: basemap
                                                                  });
                // set the map on the mapview
                mapView.map = map;
            }
        });

        // load the service
        service.load();
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.