Feature layer (geodatabase)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
// [WriteFile Name=FeatureLayer_Geodatabase, Category=Features]
// [Legal]
// Copyright 2016 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import QtQuick.Controls 2.2
import QtQuick.Layouts 1.3
import Esri.ArcGISRuntime 100.11
import Esri.ArcGISExtras 1.1

Rectangle {
    width: 800
    height: 600

    readonly property url dataPath: System.userHomePath + "/ArcGIS/Runtime/Data/"
    property string errorMessage: ""

    // Map view UI presentation at top
    MapView {
        anchors.fill: parent

        Map {
            id: map

            // set an initial viewpoint
            ViewpointCenter {
                Point {
                    x: -13214155
                    y: 4040194
                    spatialReference: SpatialReference { wkid: 3857 }
                }
                targetScale: 35e4
            }

            //! [FeatureLayer Geodatabase add basemap]
            // create a basemap from a local vector tile package
            Basemap {
                ArcGISVectorTiledLayer {
                    url: dataPath + "vtpk/LosAngeles.vtpk"
                }
            }
            //! [FeatureLayer Geodatabase add basemap]

            //! [FeatureLayer Geodatabase create]
            // create a feature layer
            FeatureLayer {
                // obtain the feature table from the geodatabase by name
                featureTable: gdb.geodatabaseFeatureTablesByTableName["Trailheads"] ?
                                  gdb.geodatabaseFeatureTablesByTableName["Trailheads"] :
                                  null

                // create the geodatabase
                Geodatabase {
                    id: gdb
                    path: dataPath + "geodatabase/LA_Trails.geodatabase"

                    onErrorChanged: errorMessage = error.message;
                }

                onErrorChanged: errorMessage = error.message;
            }
            //! [FeatureLayer Geodatabase create]

            onErrorChanged: errorMessage = error.message;
        }

        onErrorChanged: errorMessage = error.message;
    }

    Dialog {
        modal: true
        x: Math.round(parent.width - width) / 2
        y: Math.round(parent.height - height) / 2
        standardButtons: Dialog.Ok
        visible: text.length > 0
        property alias text : textLabel.text
        property alias informativeText : detailsLabel.text
        ColumnLayout {
            Text {
                id: textLabel
                text: errorMessage
            }
            Text {
                id: detailsLabel
                text: "Please consult the README.md"
            }
        }
    }
}