Open map (URL)

// [WriteFile Name=OpenMapUrl, Category=Maps]
// [Legal]
// Copyright 2016 Esri.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

#ifdef PCH_BUILD
#include "pch.hpp"
#endif // PCH_BUILD

// sample headers
#include "OpenMapUrl.h"

// ArcGIS Maps SDK headers
#include "Basemap.h"
#include "Map.h"
#include "MapQuickView.h"
#include "MapTypes.h"

using namespace Esri::ArcGISRuntime;

OpenMapUrl::OpenMapUrl(QQuickItem* parent) :
  QQuickItem(parent)
{
}

OpenMapUrl::~OpenMapUrl() = default;

void OpenMapUrl::init()
{
  qmlRegisterType<MapQuickView>("Esri.Samples", 1, 0, "MapView");
  qmlRegisterType<OpenMapUrl>("Esri.Samples", 1, 0, "OpenMapUrlSample");
}

void OpenMapUrl::componentComplete()
{
  QQuickItem::componentComplete();

  // find QML MapView component
  m_mapView = findChild<MapQuickView*>("mapView");

  // create a new basemap instance
  Basemap* basemap = new Basemap(BasemapStyle::ArcGISImageryStandard, this);
  // create a new map instance
  Map* map = new Map(basemap, this);
  // set map on the map view
  m_mapView->setMap(map);
}

void OpenMapUrl::openMap(const QString& itemId)
{
  //! [Construct map from a webmap Url]
  // create a QUrl using the item id QString
  QString organizationPortalUrl(QStringLiteral("https://arcgis.com"));
  const QUrl webmapUrl(QString(organizationPortalUrl + "/sharing/rest/content/items/" + itemId));
  // create a new map from the webmap Url
  Map* map = new Map(webmapUrl, this);
  //! [Construct map from a webmap Url]

  // set the map to the map view
  m_mapView->setMap(map);
}

// [WriteFile Name=OpenMapUrl, Category=Maps]
// [Legal]
// Copyright 2016 Esri.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

#ifndef OPEN_MAP_URL_H
#define OPEN_MAP_URL_H

// Qt headers
#include <QQuickItem>

namespace Esri::ArcGISRuntime
{
  class MapQuickView;
}

class QString;

class OpenMapUrl : public QQuickItem
{
  Q_OBJECT

public:
  explicit OpenMapUrl(QQuickItem* parent = nullptr);
  ~OpenMapUrl() override;

  void componentComplete() override;
  static void init();
  Q_INVOKABLE void openMap(const QString& itemId);

private:
  Esri::ArcGISRuntime::MapQuickView* m_mapView = nullptr;
};

#endif // OPEN_MAP_URL_H

// [WriteFile Name=OpenMapUrl, Category=Maps]
// [Legal]
// Copyright 2016 Esri.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import Esri.Samples

OpenMapUrlSample {
    id: openMapUrlSample
    width: 800
    height: 600

    // add a mapView component
    MapView {
        id: mapView
        anchors.fill: parent
        objectName: "mapView"

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
        }
    }

    // Create a list model with information about different webmaps
    ListModel {
       id: webmapsListModel
       ListElement { itemTitle: "Geology of United States"; imageUrl: "qrc:/Samples/Maps/OpenMapUrl/geology.jpg"; itemId: "92ad152b9da94dee89b9e387dfe21acd"}
       ListElement { itemTitle: "Terrestrial Ecosystems of the World"; imageUrl: "qrc:/Samples/Maps/OpenMapUrl/ecosystems.png"; itemId: "5be0bc3ee36c4e058f7b3cebc21c74e6"}
       ListElement { itemTitle: "Recent Hurricanes, Cyclones, and Typhoons"; imageUrl: "qrc:/Samples/Maps/OpenMapUrl/traces.png"; itemId: "064f2e898b094a17b84e4a4cd5e5f549"}
    }

    // Create a delegate for how the webmaps display in the view
    Component {
       id: webmapsDelegate
       Item {
           width: parent.width
           height: 65

           Row {
               spacing: 10
               Image {
                   source: imageUrl
                   width: 100
                   height: 65
               }
               Row {
                   anchors.verticalCenter: parent.verticalCenter
                   Text {
                       width: 100
                       text: itemTitle
                       wrapMode: Text.WordWrap
                   }
               }
           }
           MouseArea {
               anchors.fill: parent
               // When an item in the list view is clicked
               onClicked: {
                    webmapsListView.currentIndex = index;
                   // Call C++ invokable function to open the map from a webmap Url using this item id
                    openMap(itemId);
                    mapPickerWindow.visible = false;
               }
           }
       }
    }

    // Create a window to display the different webmaps that can be selected
    Rectangle {
       id: mapPickerWindow
       anchors.fill: parent
       color: "transparent"

       Rectangle {
           anchors.fill: parent
           color: "#60000000"
       }

       MouseArea {
           anchors.fill: parent
           onClicked: mouse => mouse.accepted = true
           onWheel: wheel => wheel.accepted = true
       }

       Rectangle {
           anchors.centerIn: parent
           width: 250
           height: 200
           color: "lightgrey"
           opacity: .8
           radius: 5
           border {
               color: "#4D4D4D"
               width: 1
           }

           // Create a list view to display the items
           ListView {
               id: webmapsListView
               anchors {
                   fill: parent
                   margins: 10
               }
               // Assign the model to the list model of webmaps
               model: webmapsListModel
               // Assign the delegate to the delegate created above
               delegate: webmapsDelegate
               spacing: 10
               clip: true
               highlightFollowsCurrentItem: true
               highlight: Rectangle { color: "lightsteelblue"; radius: 5 }
               focus: true
           }
       }
    }

    // Create a button to show the map picker window
    Rectangle {
       id: switchButton
       property bool pressed: false
       visible: !mapPickerWindow.visible
       anchors {
           right: parent.right
           bottom: parent.bottom
           rightMargin: 20
           bottomMargin: 40
       }

       width: 45
       height: width
       color: pressed ? "#959595" : "#D6D6D6"
       radius: 100
       border {
           color: "#585858"
           width: 1
       }

       Image {
           anchors.centerIn: parent
           width: 35
           height: width
           source: "qrc:/Samples/Maps/OpenMapUrl/SwitchMap.png"
       }

       MouseArea {
           anchors.fill: parent
           onPressed: switchButton.pressed = true
           onReleased: switchButton.pressed = false
           onClicked: {
               // Show the add window when it is clicked
               mapPickerWindow.visible = true;
           }
       }
    }
}

// [Legal]
// Copyright 2015 Esri.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

// sample headers
#include "OpenMapUrl.h"

// ArcGIS Maps SDK headers
#include "ArcGISRuntimeEnvironment.h"

// Qt headers
#include <QCommandLineParser>
#include <QDir>
#include <QGuiApplication>
#include <QQmlEngine>
#include <QQuickView>
#include <QSettings>

// Platform specific headers
#ifdef Q_OS_WIN
#include <Windows.h>
#endif

#define STRINGIZE(x) #x
#define QUOTE(x) STRINGIZE(x)

int main(int argc, char *argv[])
{
  Esri::ArcGISRuntime::ArcGISRuntimeEnvironment::setUseLegacyAuthentication(false);
  QGuiApplication app(argc, argv);
  app.setApplicationName(QString("OpenMapUrl"));

  // Use of ArcGIS location services, such as basemap styles, geocoding, and routing services,
  // requires an access token. For more information see
  // https://links.esri.com/arcgis-runtime-security-auth.

  // The following methods grant an access token:

  // 1. User authentication: Grants a temporary access token associated with a user's ArcGIS account.
  // To generate a token, a user logs in to the app with an ArcGIS account that is part of an
  // organization in ArcGIS Online or ArcGIS Enterprise.

  // 2. API key authentication: Get a long-lived access token that gives your application access to
  // ArcGIS location services. Go to the tutorial at https://links.esri.com/create-an-api-key.
  // Copy the API Key access token.

  const QString accessToken = QString("");

  if (accessToken.isEmpty())
  {
      qWarning() << "Use of ArcGIS location services, such as the basemap styles service, requires" <<
                    "you to authenticate with an ArcGIS account or set the API Key property.";
  }
  else
  {
      Esri::ArcGISRuntime::ArcGISRuntimeEnvironment::setApiKey(accessToken);
  }

  // Initialize the sample
  OpenMapUrl::init();

  // Initialize application view
  QQuickView view;
  view.setResizeMode(QQuickView::SizeRootObjectToView);

  // Add the import Path
  view.engine()->addImportPath(QDir(QCoreApplication::applicationDirPath()).filePath("qml"));

  QString arcGISRuntimeImportPath = QUOTE(ARCGIS_RUNTIME_IMPORT_PATH);

 #if defined(LINUX_PLATFORM_REPLACEMENT)
  // on some linux platforms the string 'linux' is replaced with 1
  // fix the replacement paths which were created
  QString replaceString = QUOTE(LINUX_PLATFORM_REPLACEMENT);
  arcGISRuntimeImportPath = arcGISRuntimeImportPath.replace(replaceString, "linux", Qt::CaseSensitive);
 #endif

  // Add the Runtime and Extras path
  view.engine()->addImportPath(arcGISRuntimeImportPath);

  // Set the source
  view.setSource(QUrl("qrc:/Samples/Maps/OpenMapUrl/OpenMapUrl.qml"));

  view.show();

  return app.exec();
}