Map reference scale

View inQMLC++
View on GitHub
Sample viewer app

Set the map's reference scale and which feature layers should honor the reference scale.

screenshot

Use case

Setting a reference scale on a Map fixes the size of symbols and text to the desired height and width at that scale. As you zoom in and out, symbols and text will increase or decrease in size accordingly. When no reference scale is set, symbol and text sizes remain the same size relative to the MapView.

Map annotations are typically only relevant at certain scales. For instance, annotations to a map showing a construction site are only relevant at that construction site's scale. So, when the map is zoomed out that information shouldn't scale with the MapView, but should instead remain scaled with the Map.

How to use the sample

  • Use the drop box at the top to set the map's reference scale (1:500,000 1:250,000 1:100,000 1:50,000).
  • Click the button to set the map scale to the reference scale.
  • Use the menu checkboxes in the layer menu to set which feature layers should honor the reference scale.

How it works

  1. Get and set the reference scale property on the Map object.
  2. Get and set the scale symbols property on each individual FeatureLayer object.

Relevant API

  • Map
  • FeatureLayer

Additional information

The map reference scale should normally be set by the map's author and not exposed to the end user like it is in this sample.

Tags

map, reference scale, scene

Sample Code

MapReferenceScale.qmlMapReferenceScale.cppMapReferenceScale.h
                                                                                                                                                   
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
// [WriteFile Name=MapReferenceScale, Category=Maps]
// [Legal]
// Copyright 2019 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.12
import QtQuick.Controls 2.12
import Esri.Samples 1.0
import QtQuick.Layouts 1.12

Item {
    readonly property var referenceScales: [500000, 250000, 100000, 50000]

    MapView {
        id: myMapView
        anchors.fill: parent
    }

    Rectangle {
        anchors {
            margins: 5
            left: parent.left
            top: parent.top
        }
        width: childrenRect.width
        height: childrenRect.height
        color: "#000000"
        opacity: .75
        radius: 5

        ColumnLayout {
            Text {
                color: "#ffffff"
                text: "Current Map Scale 1:%1".arg(Math.round(mapReferenceScaleSampleModel.currentMapScale))
                Layout.fillWidth: true
                Layout.margins: 3
                font {
                    weight: Font.DemiBold
                    pointSize: 10
                }
            }

            Text {
                color: "#ffffff"
                text: qsTr("Select a new reference scale")
                Layout.fillWidth: true
                Layout.margins: 3
                font {
                    weight: Font.DemiBold
                    pointSize: 10
                }
            }

            ComboBox {
                id: scales
                font {
                    weight: Font.DemiBold
                    pointSize: 10
                }
                Layout.margins: 3
                Layout.fillWidth: true
                model: ["1:500000","1:250000","1:100000","1:50000"]
                Component.onCompleted: mapReferenceScaleSampleModel.currentMapScale = referenceScales[scales.currentIndex];
                onActivated: mapReferenceScaleSampleModel.currentMapScale = referenceScales[scales.currentIndex];
            }

            Button {
                text: qsTr("Set Map Scale to Reference Scale")
                font {
                    weight: Font.DemiBold
                    pointSize: 10
                }
                Layout.margins: 3
                Layout.fillWidth: true
                onClicked: mapReferenceScaleSampleModel.setMapScaleToReferenceScale(referenceScales[scales.currentIndex]);
            }
        }
    }

    Rectangle {
        anchors {
            margins: 5
            right: parent.right
            top: parent.top
        }
        width: childrenRect.width
        height: childrenRect.height
        color: "#000000"
        opacity: .75
        radius: 5

        ColumnLayout {
            Text {
                text: qsTr("Apply Reference Scale")
                horizontalAlignment: Text.AlignHCenter
                Layout.fillWidth: true
                Layout.margins: 2
                font {
                    weight: Font.DemiBold
                    pointSize: 10
                }
                color: "#ffffff"
            }

            Repeater {
                // Assign the model to the list model of operational layers
                id: featureLayerRepeater
                model: mapReferenceScaleSampleModel.layerInfoListModel
                width: childrenRect.width
                height: childrenRect.height

                // Assign the delegate to display text next to checkbox as a row
                delegate: Row {
                    CheckBox {
                        id: featureLayerBox
                        checked: true
                        onCheckStateChanged: mapReferenceScaleSampleModel.featureLayerScaleSymbols(name,featureLayerBox.checked);
                    }
                    Text {
                        id: featureLayerText
                        text: name
                        height: featureLayerBox.height
                        verticalAlignment: Text.AlignVCenter
                        font.pointSize: 10
                        color: "#ffffff"
                    }
                }
            }
        }
    }
    // Declare the C++ instance which creates the scene etc. and supply the view
    MapReferenceScaleSample {
        id: mapReferenceScaleSampleModel
        mapView: myMapView
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.