Add ENC exchange set

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
// [WriteFile Name=AddEncExchangeSet, Category=Layers]
// [Legal]
// Copyright 2019 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import Esri.ArcGISRuntime
import Esri.ArcGISExtras

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property url dataPath: {
        Qt.platform.os === "ios" ?
                    System.writableLocationUrl(System.StandardPathsDocumentsLocation) + "/ArcGIS/Runtime/Data/" :
                    System.writableLocationUrl(System.StandardPathsHomeLocation) + "/ArcGIS/Runtime/Data/"
    }
    property var loadedEncLayerCount: 0

    Component.onCompleted: {
        // set resource path
        EncEnvironmentSettings.resourcePath = dataPath + "ENC/hydrography";

        // load the EncExchangeSet
        encExchangeSet.load();
    }

    MapView {
        id: mapView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
        }

        Map {
            id: map
            Basemap {
                initStyle: Enums.BasemapStyleArcGISOceans
            }

            EncExchangeSet {
                id: encExchangeSet
                paths: [dataPath + "ENC/ExchangeSetwithoutUpdates/ENC_ROOT/CATALOG.031"]

                property var layers: []

                // connect to the load status changed signal
                onLoadStatusChanged: {
                    if (loadStatus === Enums.LoadStatusFailedToLoad) {
                        console.log("fail to load", error.message, error.additionalMessage);
                        return;
                    }

                    if (loadStatus !== Enums.LoadStatusLoaded) {
                        return;
                    }

                    // loop through the datasets
                    for (let i = 0; i < datasets.length; i++) {

                        // create an EncCell from each dataset
                        const encCell = ArcGISRuntimeEnvironment.createObject("EncCell", {
                                                                                  dataset: datasets[i]
                                                                              }, map);

                        // create an EncLayer from each cell
                        const encLayer = ArcGISRuntimeEnvironment.createObject("EncLayer", {
                                                                                   cell: encCell
                                                                               }, map);
                        layers.push(encLayer);

                        // connect to loadStatusChanged for each layer
                        encLayer.loadStatusChanged.connect(()=> {
                            if (encLayer.loadStatus === Enums.LoadStatusLoaded) {
                                loadedEncLayerCount++;
                            }

                            // loop through the layers and zoom to the combined full extent
                            if (loadedEncLayerCount === datasets.length) {
                                const fullExtents = [];
                                map.operationalLayers.forEach(layer => fullExtents.push(layer.fullExtent));
                                const fullExtentOfLayers = GeometryEngine.combineExtentsOfGeometries(fullExtents);
                                mapView.setViewpointGeometry(fullExtentOfLayers)
                            }
                        });

                        // add the layer to the map
                        map.operationalLayers.append(encLayer);
                    }
                }
            }
        }
    }
}