Use augmented reality (AR) to quickly explore a scene more naturally than you could with a touch or mouse interface.
Use case
You can use AR to drop into an area and visualize information, like a proposed development or a historical model of a city. You could use flyover AR to explore a city by walking through it virtually.
How to use the sample
When you open the sample, you'll be viewing the scene from above. You can walk around, using your device as a window into the scene. Try moving vertically to get closer to the ground.
How it works
- Create the
ArcGISARViewand add it to the view. - Create the scene, add content, then display it.
- When the content you want to view loads, get its center point and use that to create the origin camera for the AR view. Note that the altitude should be set so that all scene content is visible. For a city, a good value might be a bit higher than the tallest building. The sample uses 250 meters in the absence of tall buildings in the sample data.
- Set the translation factor so that you can move through the scene easily. With a translation factor of 1000, you will move 1000 feet in the scene for every foot you move the physical device.
- Set the space effect to
Enums.SpaceEffectStarsand atmosphere effect toEnums.AtmosphereEffectRealisticto create an immersive experience.
Relevant API
- ArcGISARView
- SceneView
About the data
This sample uses a sample integrated mesh layer provided by Vricon. The integrated mesh layer shows an area around the US-Mexico border.
The world elevation service is used to show terrain while the integrated mesh layer loads.
Additional information
Flyover AR is one of three main patterns for working with geographic information in augmented reality. Augmented reality is made possible with the ArcGIS Maps SDK for Qt Toolkit. See Augmented reality in the guide for more information about augmented reality and adding it to your app.
Clone the toolkit repo - Required for AR samples
Change directory into your locally cloned samples repo and then use git clone to get a copy of the ArcGIS Maps SDK for Qt Toolkit.
# Change directory to the clone of the samples repository
# Clone the toolkit repository into the current directory in terminal
$ cd /arcgis-maps-samples-qt
$ git clone https://github.com/Esri/arcgis-maps-sdk-toolkit-qt.git
Cloning the toolkit in this location will allow for the samples to automatically pick it up. If you wish to place the toolkit in another location, you will need to update the samples project file accordingly to locate the necessary .pri file.
For more information on the Augmented Reality (AR) toolkit, including the steps required to deploy to Android and iOS, see the AR README on GitHub.
Tags
augmented reality, bird's eye, birds-eye-view, fly over, flyover, mixed reality, translation factor
Sample Code
// [WriteFile Name=ExploreScenesInFlyoverAR, Category=AR]
// [Legal]
// Copyright 2020 Esri.
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]
import QtQuick
import QtQuick.Controls
import Esri.ArcGISRuntime
import Esri.ArcGISExtras
import Esri.ArcGISArToolkit
Rectangle {
id: rootRectangle
clip: true
width: 800
height: 600
ArcGISArView {
id: arcGISArView
anchors.fill: parent
tracking: true
sceneView: sceneView
}
SceneView {
id: sceneView
anchors.fill: parent
Component.onCompleted: {
// Set the focus on SceneView to initially enable keyboard navigation
forceActiveFocus();
}
Scene {
id: scene
Basemap {
initStyle: Enums.BasemapStyleArcGISImageryStandard
}
Surface {
opacity: 0.0
ArcGISTiledElevationSource {
url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
}
}
// create the integrated mesh layer
IntegratedMeshLayer {
id: integratedMeshLayer
url: "https://www.arcgis.com/home/item.html?id=5c55d0d1f21e489193cdeff11460a28c"
onLoadStatusChanged: {
if (loadStatus !== Enums.LoadStatusLoaded)
return;
// Enable subsurface navigation. This allows you to look at the scene from below.
sceneView.scene.baseSurface.navigationConstraint = Enums.NavigationConstraintStayAbove;
scene.baseSurface.opacity = 1.0;
// Start with the camera at the center of the mesh layer.
const viewPoint = ArcGISRuntimeEnvironment.createObject("Point", {
y: integratedMeshLayer.fullExtent.center.y,
x: integratedMeshLayer.fullExtent.center.x,
z: 250.0
});
const originCamera = ArcGISRuntimeEnvironment.createObject("Camera", {
location: viewPoint,
heading: 0,
pitch: 90,
roll: 0
});
arcGISArView.originCamera = originCamera;
// Set the translation factor to enable rapid movement through the scene.
arcGISArView.translationFactor = 1000;
// Enable atmosphere and space effects for a more immersive experience.
sceneView.spaceEffect = Enums.SpaceEffectStars;
sceneView.atmosphereEffect = Enums.AtmosphereEffectRealistic;
}
onErrorChanged: {
console.log("(%1)[%2] %3 - %4".arg(error.code).arg(error.domain).arg(error.message).arg(error.additionalMessage));
}
}
}
}
}