Choose camera controller

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
// [WriteFile Name=ChooseCameraController, Category=Scenes]
// [Legal]
// Copyright 2019 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import Esri.ArcGISRuntime
import Esri.ArcGISExtras
import QtQuick.Controls
import QtQuick.Layouts

Rectangle {
    clip: true
    width: 800
    height: 600

    readonly property url dataPath: {
        Qt.platform.os === "ios" ?
                    System.writableLocationUrl(System.StandardPathsDocumentsLocation) + "/ArcGIS/Runtime/Data/3D" :
                    System.writableLocationUrl(System.StandardPathsHomeLocation) + "/ArcGIS/Runtime/Data/3D"
    }
    readonly property real longitude: -109.929589
    readonly property real latitude: 38.43500
    readonly property real distance: 5000

    GlobeCameraController {
        id: globeController
    }

    Point {
        id: theCrater
        x: longitude
        y: latitude
        z: distance
        spatialReference: SpatialReference { wkid: 4326 }
    }

    OrbitLocationCameraController {
        id: orbitLocationCtrlr
        targetLocation: theCrater
        cameraDistance: distance
    }

    OrbitGeoElementCameraController{
        id: orbitPlaneCtrlr
        targetGeoElement: thePlane
        cameraDistance: distance / 2
    }

    SceneView {
        id: sceneView
        anchors.fill: parent

        Scene {
            id: scene
            Basemap {
                initStyle: Enums.BasemapStyleArcGISImageryStandard
            }

            Surface {
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }
        }

        GraphicsOverlay {
            id: graphicsOverlay

            LayerSceneProperties {
                surfacePlacement: Enums.SurfacePlacementRelative
            }

            ModelSceneSymbol {
                id: mms
                url: dataPath + "/Bristol/Collada/Bristol.dae"
                scale: 10.0
                heading: 0.0
            }

            Graphic {
                id: thePlane
                symbol: mms

                geometry: Point {
                    x: longitude
                    y: latitude
                    z: distance / 2
                    spatialReference: sceneView.spatialReference
                }
            }
        }

        Component.onCompleted: {
            // Set the focus on SceneView to initially enable keyboard navigation
            forceActiveFocus();

            // set viewpoint to the specified camera
            sceneView.setViewpointCamera(camera);
        }
    }

    Camera {
        id: camera
        heading: 0.0
        pitch: 0.0
        roll: 0.0
        location: theCrater
    }

    // Create a rectangle to display the GUI
    Rectangle {
        width: childrenRect.width
        height: childrenRect.height
        color: "lightgrey"
        opacity: 0.8
        radius: 5
        anchors {
            margins: 10
            left: parent.left
            top: parent.top
        }
        border {
            color: "#4D4D4D"
            width: 1
        }

        ColumnLayout {

            Text {
                Layout.margins: 5
                Layout.fillWidth: true
                text: "Choose camera controller"
                clip: true
                font {
                    pointSize: 14
                    bold: true
                }
            }

            RadioButton {
                id: orbitAroundAeroplane
                Layout.fillWidth: true
                text: "Orbit camera around plane"
                onCheckedChanged: {
                    if (checked) {
                        sceneView.cameraController = orbitPlaneCtrlr;
                    }
                }
            }

            RadioButton {
                id: orbitLocation
                Layout.fillWidth: true
                text: "Orbit camera around crater"
                onCheckedChanged: {
                    if (checked) {
                        sceneView.cameraController = orbitLocationCtrlr;
                    }
                }
            }

            RadioButton {
                id: orbitAroundGlobe
                Layout.fillWidth: true
                checked: true
                text: "Free pan round the globe"
                onCheckedChanged: {
                    if (checked) {
                        sceneView.cameraController = globeController;
                    }
                }
            }
        }
    }
}