Terrain exaggeration

View inQMLC++
View on GitHub
Sample viewer app

Vertically exaggerate terrain in a scene.

screenshot

Use case

Vertical exaggeration can be used to emphasize subtle changes in a surface. This can be useful in creating visualizations of terrain where the horizontal extent of the surface is significantly greater than the amount of vertical change in the surface. A fractional vertical exaggeration can be used to flatten surfaces or features that have extreme vertical variation.

How to use the sample

Use the slider to update terrain exaggeration.

How it works

  1. Create a scene.
  2. Create and add a surface with an ArcGISTiledElevationService.

    • The surface visualizes the elevation source.
    • An elevation source defines the terrain based on a digital elevation model (DEM) or digital terrain model (DTM).
  3. Create a slider object.
  4. Bind the surface's elevationExaggeration property to the slider's value.

Relevant API

  • Scene
  • Scene.baseSurface
  • Surface
  • Surface.elevationExaggeration

Tags

3D, DEM, DTM, elevation, scene, surface, terrain

Sample Code

TerrainExaggeration.qml
                                                                                                           
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
// [WriteFile Name=TerrainExaggeration, Category=Scenes]
// [Legal]
// Copyright 2018 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.11

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    SceneView {
        id: sceneView
        anchors.fill: parent

        // add a Scene to the SceneView
        Scene {
            // add the BasemapNationalGeographic basemap to the scene
            BasemapNationalGeographic {}

            // add a surface...surface is a default property of scene
            Surface {
                // add an arcgis tiled elevation source...elevation source is a default property of surface
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
                // elevationExaggeration is bound to the value of the slider
                elevationExaggeration: slider.value
            }
        }

        Component.onCompleted: {
            sceneView.setViewpointCamera(camera);
        }

        // Slider UI presentation at bottom
        Rectangle {
            anchors {
                bottom: sceneView.attributionTop
                horizontalCenter: parent.horizontalCenter
            }

            width: childrenRect.width
            height: childrenRect.height
            radius: 10
            opacity: 0.8

            // sliderCombo: A slider and text for its value
            Row {
                id: sliderCombo
                spacing: 5

                Slider {
                    id: slider
                    opacity: 0.7
                    anchors {
                        verticalCenter: parent.verticalCenter
                    }
                    // Slider controls exagerration of the elevation of
                    // the terrain
                    from: 1.0
                    to: 10.0
                }

                Text {
                    anchors {
                        verticalCenter: parent.verticalCenter
                        margins: 5
                    }
                    horizontalAlignment: TextInput.AlignHCenter
                    font.pixelSize: 20
                    text: slider.value.toPrecision(2);
                }
            }
        }
    }

    Camera {
        id: camera
        distance: 0
        heading: 7
        pitch: 70
        roll: 0.0

        Point {
            x: -119.9616962169934
            y: 46.7000413426849
            z: 3183
            spatialReference: SpatialReference { wkid: 4326 }
        }
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.