Scene properties expressions

View inQMLC++
View on GitHub
Sample viewer app

Update the orientation of a graphic using expressions based on its attributes.

screenshot

Use case

Instead of reading the attribute and changing the rotation on the symbol for a single graphic (a manual CPU operation), you can bind the rotation to an expression that applies to the whole overlay (an automatic GPU operation). This usually results in a noticeable performance boost (smooth rotations).

How to use the sample

Adjust the heading and pitch sliders to rotate the cone.

How it works

  1. Create a new graphics overlay.
  2. Create a simple renderer and set its scene properties.
  3. Set the heading expression to [HEADING].
  4. Apply the renderer to the graphics overlay.
  5. Create a graphic and add it to the overlay.
  6. To update the graphic's rotation, update the HEADING or PITCH property in the graphic's attributes.

Relevant API

  • Graphic.attributes
  • GraphicsOverlay
  • SceneProperties
  • SceneProperties.headingExpression
  • SceneProperties.pitchExpression
  • SimpleRenderer
  • SimpleRenderer.rendererSceneProperties

Tags

3D, expression, graphics, heading, pitch, rotation, scene, symbology

Sample Code

ScenePropertiesExpressions.qml
                                                                                                                                                                                          
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
// [WriteFile Name=ScenePropertiesExpressions, Category=Scenes]
// [Legal]
// Copyright 2019 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import Esri.ArcGISRuntime 100.12
import QtQuick.Controls 2.2

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property real longitude: -118.71
    readonly property real latitude: 32.09
    readonly property real altitude: 100000.0
    readonly property int coneDimension: 10000
    readonly property real initialPitch: 90.0
    readonly property real initialHeading: 180.0
    readonly property string headingStr: "heading"
    readonly property string pitchStr: "pitch"

    SceneView {
        id: sceneView
        anchors.fill: parent

        Scene {
            id: scene
            Basemap {
                initStyle: Enums.BasemapStyleArcGISImageryStandard
            }

            Surface {
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }
        }

        // add a graphics overlay
        GraphicsOverlay {
            id: graphicsOverlay
            LayerSceneProperties {
                surfacePlacement: Enums.SurfacePlacementAbsolute
            }

            SimpleRenderer {
                id: sceneRenderer
                RendererSceneProperties {
                    id: renderProps
                    headingExpression: "["+headingStr+"]"
                    pitchExpression:  "["+pitchStr+"]"
                }
            }

            Graphic {
                id: coneGraphic

                geometry: Point {
                    x: longitude
                    y: latitude
                    z: altitude
                    spatialReference: sceneView.spatialReference
                }

                SimpleMarkerSceneSymbol{
                    style: Enums.SimpleMarkerSceneSymbolStyleCone
                    color: "red"
                    width: coneDimension
                    depth: coneDimension
                    height: coneDimension * 2
                    anchorPosition: Enums.SceneSymbolAnchorPositionCenter
                }

                Component.onCompleted: {
                    coneGraphic.attributes.insertAttribute(headingStr, initialHeading);
                    coneGraphic.attributes.insertAttribute(pitchStr, initialPitch);
                }
            }
        }

        Component.onCompleted: {
            // set viewpoint to the specified camera
            setViewpointCameraAndWait(camera);
        }
    }

    Rectangle {
        anchors.fill: sliderColumn
        color: "lightblue"
    }

    Column{
        id: sliderColumn

        spacing: 4

        anchors {
            left: parent.left
            top: parent.top
        }

        height: childrenRect.height

        Text {
            anchors {
                margins: 5
            }
            text: pitchStr + ": " + pitchSlider.value.toFixed(0)
            font.pixelSize: 20
            verticalAlignment: Text.AlignTop
        }

        Slider{
            id: pitchSlider
            opacity: 0.7
            height: 64

            // slider controls degrees of rotation:
            from: -90
            to: 90
            value: initialPitch
            anchors {
                margins: 5
            }

            onValueChanged: {
                coneGraphic.attributes.replaceAttribute(pitchStr, value);
            }
        }

        Text {
            anchors {
                margins: 5
            }
            text: headingStr + ": " + headingSlider.value.toFixed(0)
            verticalAlignment: Text.AlignTop
            font.pixelSize: 20
        }

        Slider{
            id: headingSlider
            opacity: 0.7
            height: 64

            // slider controls degrees of rotation:
            from: 0
            to: 360
            value: initialHeading
            anchors {
                margins: 5
            }

            onValueChanged: {
                coneGraphic.attributes.replaceAttribute(headingStr, value);
            }
        }
    }

    Camera {
        id: camera
        heading: 0.0
        pitch: 45.0
        roll: 0.0

        Point {
            x: longitude
            y: latitude - 1.0 // place the camera somewhat south of the cone
            z: altitude * 2.0 // place the camera somewhat higher than the cone
            spatialReference: SpatialReference { wkid: 4326 }
        }
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.