Graphics overlay (dictionary renderer) 3D

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
// [WriteFile Name=GODictionaryRenderer_3D, Category=DisplayInformation]
// [Legal]
// Copyright 2016 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import Esri.ArcGISRuntime
import Esri.ArcGISExtras
import Esri.samples

Rectangle {
    width: 800
    height: 600

    readonly property url dataPath: {
        Qt.platform.os === "ios" ?
                    System.writableLocationUrl(System.StandardPathsDocumentsLocation) + "/ArcGIS/Runtime/Data" :
                    System.writableLocationUrl(System.StandardPathsHomeLocation) + "/ArcGIS/Runtime/Data"
    }

    /*
     * Create SceneView that contains a Scene with the Imagery Basemap, as well as a GraphicsOverlay
     * for the military symbols.
     */
    SceneView {
        id: sceneView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on SceneView to initially enable keyboard navigation
            forceActiveFocus();
        }

        Scene {
            id: scene
            Basemap {
                initStyle: Enums.BasemapStyleArcGISImageryStandard
            }
            Surface {
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }

            onLoadStatusChanged: {
                if (loadStatus !== Enums.LoadStatusLoaded)
                    return;

                // Read the XML file and create a graphic from each entry
                const parsedXml = xmlParser.parseXmlFileAsync(dataPath + "/xml/arcade_style/Mil2525DMessages.xml");

                // Zoom to graphics
                /*
                 * Create a camera directly above the center of the features, and then rotate that
                 * camera around the center to tip it.
                 */

                const initialLocation = ArcGISRuntimeEnvironment.createObject("Point", {x: -2.0344707, y: 51.29712})
                let camera = ArcGISRuntimeEnvironment.createObject("Camera", {
                                                                       location: initialLocation,
                                                                       heading: 0,
                                                                       pitch: 70,
                                                                       roll: 0,
                                                                       distance: 15000
                                                                   });
                sceneView.setViewpointCameraAndWait(camera);
            }
        }
        GraphicsOverlay {
            id: graphicsOverlay
            renderingMode: Enums.GraphicsRenderingModeDynamic

            DictionaryRenderer {
                dictionarySymbolStyle: Factory.DictionarySymbolStyle.createFromFile(dataPath + "/styles/arcade_style/mil2525d.stylx")
            }
        }
    }

    ProgressBar {
        id: progressBar_loading
        anchors {
            horizontalCenter: parent.horizontalCenter
            bottom: parent.bottom
            margins: 5
        }
        indeterminate: true
    }

    XmlParser {
        id: xmlParser

        onXmlParseComplete: (parsedXml) => {
                                parsedXml.forEach(element => {createGraphicFromElement(element)});
                                progressBar_loading.visible = false;
                            }
    }

    function createGraphicFromElement(element) {
        let wkid = element._wkid;
        if (!wkid) {
            // If _wkid was absent, use WGS 1984 (4326) by default.
            wkid = 4326;
        }
        const pointStrings = element._control_points.split(";");
        const sr = ArcGISRuntimeEnvironment.createObject("SpatialReference", { wkid: wkid });
        let geom;
        if (pointStrings.length === 1) {
            // It's a point
            const pointBuilder = ArcGISRuntimeEnvironment.createObject("PointBuilder");
            pointBuilder.spatialReference = sr;
            const coords = pointStrings[0].split(",");
            pointBuilder.setXY(coords[0], coords[1]);
            geom = pointBuilder.geometry;
        } else {
            const builder = ArcGISRuntimeEnvironment.createObject("MultipointBuilder");
            builder.spatialReference = sr;

            for (let ptIndex = 0; ptIndex < pointStrings.length; ptIndex++) {
                const coords = pointStrings[ptIndex].split(",");
                builder.points.addPointXY(coords[0], coords[1]);
            }
            geom = builder.geometry;
        }
        if (geom) {
            const graphic = ArcGISRuntimeEnvironment.createObject("Graphic", { geometry: geom });
            graphic.attributes.attributesJson = {
                "identity": element.identity,
                "symbolset": element.symbolset,
                "symbolentity": element.symbolentity,
                "echelon": element.echelon,
                "specialentitysubtype": element.specialentitysubtype,
                "indicator": element.indicator,
                "modifier2": element.modifier2,
                "uniquedesignation": element.uniquedesignation,
                "additionalinformation": element.additionalinformation
            };
            graphicsOverlay.graphics.append(graphic);
        }
    }
}