Edit with branch versioning

View inQMLC++
View on GitHub
Sample viewer app

Create, query and edit a specific server version using service geodatabase.

screenshot

Use case

Workflows often progress in discrete stages, with each stage requiring the allocation of a different set of resources and business rules. Typically, each stage in the overall process represents a single unit of work, such as a work order or job. To manage these, you can create a separate, isolated version and modify it. Once this work is complete, you can integrate the changes into the default version.

How to use the sample

Once loaded, the map will zoom to the extent of the feature layer. The current version is indicated at the top of the map. Click "Create Version" to open a dialog to specify the version information (name, access, and description). See the Additional information section for restrictions on the version name.

Click "Create" to create the version with the information that you specified. Select a feature to edit an attribute and/or click a second time to relocate the point.

Click the button in the top left corner to switch back and forth between the version you created and the default version. Edits will automatically be applied to your version when switching to the default version.

How it works

  1. Create and load a ServiceGeodatabase with a feature service URL that has enabled Version Management.
  2. Get the ServiceFeatureTable from the service geodatabase.
  3. Create a FeatureLayer from the service feature table.
  4. Create ServiceVersionParameters with a unique name, VersionAccess, and description.

    • Note - See the additional information section for more restrictions on the version name.
  5. Create a new version calling ServiceGeodatabase.createVersion passing in the service version parameters.
  6. Switch to the version you have just created using ServiceGeodatabase.switchVersion, passing in the version name obtained from ServiceGeodatabase.createVersionResult.
  7. Select a Feature from the map to edit its "TYPDAMAGE" attribute and location.
  8. Apply these edits to your version by calling ServiceGeodatabase.applyEdits.
  9. Switch back and forth between your version and the default version to see how the two versions differ.

Relevant API

  • FeatureLayer
  • ServiceFeatureTable
  • ServiceGeodatabase
  • ServiceGeodatabase.applyEdits
  • ServiceGeodatabase.createVersion
  • ServiceGeodatabase.createVersionResult
  • ServiceGeodatabase.switchVersion
  • ServiceVersionInfo
  • ServiceVersionParameters
  • VersionAccess

About the data

The feature layer used in this sample is Damage to commercial buildings located in Naperville, Illinois.

Additional information

Credentials:

  • Username: editor01
  • Password: S7#i2LWmYH75

The name of the version must meet the following criteria:

  1. Must not exceed 62 characters
  2. Must not include: Period (.), Semicolon (;), Single quotation mark ('), Double quotation mark (")
  3. Must not include a space for the first character
  4. Note - the version name will have the username and a period (.) prepended to it. E.g "editor01.MyNewUniqueVersionName"

Branch versioning access permission:

  1. VersionAccess.Public - Any portal user can view and edit the version.
  2. VersionAccess.Protected - Any portal user can view, but only the version owner, feature layer owner, and portal administrator can edit the version.
  3. VersionAccess.Private - Only the version owner, feature layer owner, and portal administrator can view and edit the version.

Tags

branch versioning, edit, version control, version management server

Sample Code

EditWithBranchVersioning.qml
                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
// [WriteFile Name=EditWithBranchVersioning, Category=EditData]
// [Legal]
// Copyright 2020 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import Esri.ArcGISRuntime 100.12

import QtQuick.Controls 2.12
import QtQuick.Layouts 1.12
import QtGraphicalEffects 1.0
import Esri.ArcGISRuntime.Toolkit 100.12

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property var featAttributes: ["Affected", "Destroyed", "Inaccessible", "Minor", "Major"]
    readonly property var versionAccessModel: ["Public", "Protected", "Private"]
    property var serviceFeatureTable: null
    property var featureLayer: null
    property var selectedFeature: null
    property string featureName: ""
    property string currentTypeDamage: ""
    property string currentSgdbVersion: ""
    property string createdVersionName: ""
    property bool sgdbVersionIsDefault: sgdb.defaultVersionName === sgdb.versionName ? true : false

    MapView {
        id: mapView
        anchors.fill: parent

        onViewpointChanged: {
            clearSelectedFeature();
            callout.dismiss();
        }

        onMouseClicked: {
            busyIndicator.visible = true;
            featureLayer.clearSelection();

            // if feature is already selected, then move to new location
            if (selectedFeature) {
                const clickedPoint = mapView.screenToLocation(mouse.x, mouse.y);
                moveFeature(clickedPoint);
            } else {
                // call identify on the map view
                mapView.identifyLayerWithMaxResults(featureLayer, mouse.x, mouse.y, 5, false, 1);
            }
        }

        onIdentifyLayerStatusChanged: {
            if (identifyLayerStatus === Enums.TaskStatusCompleted) {
                // clear any previous selections
                clearSelectedFeature();

                if (identifyLayerResult.geoElements.length > 0) {
                    selectedFeature = identifyLayerResult.geoElements[0];
                    featureLayer.selectFeature(selectedFeature);
                } else {
                    busyIndicator.visible = false;
                    return;
                }

                featureName = selectedFeature.attributes.attributeValue("PLACENAME");
                currentTypeDamage = selectedFeature.attributes.attributeValue("TYPDAMAGE");

                callout.showCallout();
                busyIndicator.visible = false;
            }
        }

        calloutData {
            // HTML to style the title text by centering it, increase pt size,
            // and bolding it.
            title: "<br><font size=\"+2\">%1</font>".arg(featureName)
            location: selectedFeature ? selectedFeature.geometry : null
        }

        Callout {
            id: callout
            borderWidth: 1
            borderColor: "lightgrey"
            calloutData: parent.calloutData
            leaderPosition: leaderPositionEnum.Automatic
            onAccessoryButtonClicked: {
                for (let i=0; i < featAttributes.length; i++) {
                    if (currentTypeDamage === featAttributes[i]) {
                        typeDmgCombo.currentIndex = i;
                        break;
                    }
                }
                updateWindow.visible = true;
            }
        }

        Map {
            Basemap {
                initStyle: Enums.BasemapStyleArcGISStreets
            }
        }
    }

    ServiceGeodatabase {
        id: sgdb
        url: "https://sampleserver7.arcgisonline.com/server/rest/services/DamageAssessment/FeatureServer"

        credential: Credential {
            username: "editor01"
            password: "S7#i2LWmYH75"
        }

        onLoadStatusChanged: {
            if (loadStatus !== Enums.LoadStatusLoaded)
                return;

            currentSgdbVersion = sgdb.versionName;
            serviceFeatureTable = sgdb.table(0);
            serviceFeatureTable.updateFeatureStatusChanged.connect(()=> {
                if (serviceFeatureTable.updateFeatureStatus === Enums.TaskStatusCompleted)
                    busyIndicator.visible = false;
             });

            serviceFeatureTable.loadStatusChanged.connect(()=> {
                if (serviceFeatureTable.loadStatus !== Enums.LoadStatusLoaded)
                    return;

                mapView.setViewpointGeometry(featureLayer.fullExtent);
                busyIndicator.visible = false;
            });

            featureLayer = ArcGISRuntimeEnvironment.createObject("FeatureLayer");
            featureLayer.featureTable = serviceFeatureTable;
            mapView.map.operationalLayers.append(featureLayer);
        }

        onCreateVersionStatusChanged: {
            if (createVersionStatus === Enums.TaskStatusCompleted) {
                createdVersionName = createVersionResult.name;
                createVersionBtn.text = qsTr("Switch to default version");
                switchVersions();
            } else if (createVersionStatus === Enums.TaskStatusErrored) {
                errorText.text = qsTr("%1 - %2".arg(error.message).arg(error.additionalMessage));
                errorDialog.visible = true;
                busyIndicator.visible = false;
            }
        }

        onSwitchVersionStatusChanged: {
            if (switchVersionStatus === Enums.TaskStatusCompleted) {
                currentSgdbVersion = sgdb.versionName;
            } else if (switchVersionStatus === Enums.TaskStatusErrored) {
                errorText.text = qsTr("%1 - %2".arg(error.message).arg(error.additionalMessage));
                errorDialog.visible = true;
            }
            busyIndicator.visible = false;
        }

        onApplyEditsStatusChanged: {
            if (applyEditsStatus === Enums.TaskStatusCompleted) {
                switchVersions();
                applyEditsDialog.visible = false;

            } else if (applyEditsStatus === Enums.TaskStatusErrored) {
                errorText.text = qsTr("%1 - %2".arg(error.message).arg(error.additionalMessage));
                errorDialog.visible = true;
                return;
            }
        }

        onComponentCompleted: {
            load();
            busyIndicator.visible = true;
        }
    }

    ServiceVersionParameters {
        id: params
    }

    Button {
        id: createVersionBtn
        text: qsTr("Create Version")
        anchors {
            left: parent.left
            top: parent.top
            margins: 3
        }
        enabled: !busyIndicator.visible

        onClicked: {
            if (text === qsTr("Create Version")) {
                createVersionWindow.visible = true;
                callout.dismiss();
                updateWindow.visible = false;
            } else if (text === qsTr("Switch to default version")) {
                text = qsTr("Switch to created version")
                busyIndicator.visible = true;

                if (sgdb.hasLocalEdits()) {
                    sgdb.applyEdits();
                    applyEditsDialog.visible = true;
                } else {
                    switchVersions();
                }
                callout.dismiss();
                updateWindow.visible = false;
            } else if (text === qsTr("Switch to created version")) {
                text = qsTr("Switch to default version")
                switchVersions();
                callout.dismiss();
                updateWindow.visible = false;
            }
            clearSelectedFeature();
        }
    }

    Rectangle {
        id: currentVersionRect
        anchors{
            top: parent.top
            horizontalCenter: parent.horizontalCenter
            margins: 3
        }
        width: childrenRect.width;
        height: childrenRect.height;
        color: "#000000"
        visible: currentVersionText.text !== "" ? true : false

        ColumnLayout {
            spacing: 3
            Text {
                text: qsTr("Current version:")
                Layout.alignment: Qt.AlignHCenter
                color: "white"
            }

            Text {
                id: currentVersionText
                Layout.alignment: Qt.AlignHCenter
                text: currentSgdbVersion
                color: "white"
            }
        }
    }

    Rectangle {
        id: createVersionWindow
        anchors.centerIn: parent
        width: childrenRect.width
        height: childrenRect.height
        radius: 10
        visible: false

        GaussianBlur {
            anchors.fill: createVersionWindow
            source: mapView
            radius: 40
            samples: 20
        }

        MouseArea {
            anchors.fill: parent
            onClicked: mouse.accepted = true;
            onWheel: wheel.accepted = true;
        }

        ColumnLayout {
            anchors.margins: 5

            TextField {
                id: versionNameTextField
                placeholderText: qsTr("Name must be unique")
                Layout.alignment: Qt.AlignHCenter
                Layout.margins: 5
                validator: RegExpValidator { regExp: /\w{0,50}/ }
            }

            ComboBox {
                id: accessComboBox
                model: versionAccessModel
                Layout.fillWidth: true
                Layout.alignment: Qt.AlignHCenter
                Layout.margins: 5
            }

            TextField {
                id: descriptionTextField
                placeholderText: qsTr("Enter description")
                Layout.alignment: Qt.AlignHCenter
                Layout.margins: 5
            }

            Row {
                Layout.alignment: Qt.AlignRight
                Layout.margins: 5
                height: childrenRect.height
                spacing: 5

                Button {
                    Layout.margins: 5
                    Layout.alignment: Qt.AlignRight
                    text: qsTr("Create")
                    onClicked: {
                        createVersion(versionNameTextField.text, accessComboBox.currentValue, descriptionTextField.text);
                        busyIndicator.visible = true;
                        resetCreateVersionWindow();
                    }
                }

                Button {
                    Layout.alignment: Qt.AlignRight
                    Layout.margins: 5
                    text: qsTr("Cancel")
                    onClicked: {
                        resetCreateVersionWindow();
                    }
                }
            }
        }
    }

    // Update Window
    Rectangle {
        id: updateWindow
        anchors.centerIn: parent
        width: childrenRect.width
        height: childrenRect.height
        radius: 10
        visible: false

        GaussianBlur {
            anchors.fill: updateWindow
            source: mapView
            radius: 40
            samples: 20
        }

        MouseArea {
            anchors.fill: parent
            onClicked: mouse.accepted = true;
            onWheel: wheel.accepted = true;
        }

        GridLayout {
            columns: 2
            anchors.margins: 5

            Text {
                Layout.columnSpan: 2
                Layout.margins: 5
                Layout.alignment: Qt.AlignHCenter
                text: qsTr("Update Attributes")
                font.pixelSize: 16
            }

            Text {
                text: "TYPDAMAGE:"
                Layout.margins: 5
            }

            ComboBox {
                id: typeDmgCombo
                property int modelWidth: 0
                Layout.minimumWidth: modelWidth + leftPadding + rightPadding + indicator.width
                Layout.margins: 5
                Layout.fillWidth: true
                model: featAttributes
                enabled: !sgdbVersionIsDefault
            }

            Row {
                Layout.alignment: Qt.AlignRight
                Layout.columnSpan: 2
                height: childrenRect.height
                spacing: 5

                Button {
                    Layout.margins: 5
                    Layout.alignment: Qt.AlignRight
                    text: qsTr("Update")
                    enabled: !sgdbVersionIsDefault
                    // once the update button is clicked, hide the windows, and fetch the currently selected features
                    onClicked: {
                        updateAttribute(typeDmgCombo.currentValue);
                        updateWindow.visible = false;
                        callout.dismiss();
                        busyIndicator.visible = true;
                    }
                }

                Button {
                    Layout.alignment: Qt.AlignRight
                    Layout.margins: 5
                    text: qsTr("Cancel")
                    // once the cancel button is clicked, hide the window
                    onClicked: {
                        clearSelectedFeature();
                        updateWindow.visible = false;
                        callout.dismiss();
                    }
                }
            }
        }
    }

    function switchVersions() {
        if (!sgdbVersionIsDefault) {
            sgdb.switchVersion(sgdb.defaultVersionName);
            createVersionBtn.text = qsTr("Switch to created version");
        } else {
            sgdb.switchVersion(createdVersionName);
        }
    }

    function moveFeature(mapPoint) {
        if (!sgdbVersionIsDefault) {
            selectedFeature.geometry = mapPoint;
            selectedFeature.featureTable.updateFeature(selectedFeature);
        }
        busyIndicator.visible = false;
        clearSelectedFeature();
    }

    function clearSelectedFeature() {
        selectedFeature = null;
        if (featureLayer)
            featureLayer.clearSelection();

        callout.dismiss();
    }

    function createVersion(versionName, versionAccess, description) {
        params.name = versionName;
        params.description = description;

        if (versionAccess === "Private") {
            params.access = Enums.VersionAccessPrivate;
        } else if (versionAccess === "Protected") {
            params.access = Enums.VersionAccessProtected;
        } else if (versionAccess == "Public") {
            params.access = Enums.VersionAccessPublic;
        }
        sgdb.createVersion(params);
    }

    function resetCreateVersionWindow() {
        createVersionWindow.visible = false;
        versionNameTextField.text = "";
        descriptionTextField.text = "";
        accessComboBox.currentIndex = 0;
    }

    function updateAttribute(attributeValue) {
        busyIndicator.visible = true;
        if (!selectedFeature)
            return;

        if (sgdbVersionIsDefault) {
            clearSelectedFeature();
            return;
        }

        // update the attirbute with the selection from the combo box
        selectedFeature.attributes.replaceAttribute("TYPDAMAGE", attributeValue);
        selectedFeature.featureTable.updateFeature(selectedFeature);
    }

    //     Uncomment this section when running as standalone application
    AuthenticationView {
        anchors.fill: parent
    }

    Dialog {
        id: errorDialog
        anchors.centerIn: parent
        standardButtons: Dialog.Ok

        Text {
            id: errorText
        }
    }

    Dialog {
        id: applyEditsDialog
        x: Math.round(parent.width - width) / 2
        y: Math.round(parent.height - height) - mapView.attributionRect.height;

        Text {
            id: applyEditsText
            text: qsTr("Applying Edits")
        }
    }

    BusyIndicator {
        id: busyIndicator
        anchors.centerIn: parent
        visible: false
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.