Feature layer rendering mode (map)

View inQMLC++
View on GitHub
Sample viewer app

Render features statically or dynamically by setting the feature layer rendering mode.

screenshot

Use case

In dynamic rendering mode, features and graphics are stored on the GPU. As a result, dynamic rendering mode is good for moving objects and for maintaining graphical fidelity during extent changes, since individual graphic changes can be efficiently applied directly to the GPU state. This gives the map or scene a seamless look and feel when interacting with it. The number of features and graphics has a direct impact on GPU resources, so large numbers of features or graphics can affect the responsiveness of maps or scenes to user interaction. Ultimately, the number and complexity of features and graphics that can be rendered in dynamic rendering mode is dependent on the power and memory of the device's GPU.

In static rendering mode, features and graphics are rendered only when needed (for example, after an extent change) and offloads a significant portion of the graphical processing onto the CPU. As a result, less work is required by the GPU to draw the graphics, and the GPU can spend its resources on keeping the UI interactive. Use this mode for stationary graphics, complex geometries, and very large numbers of features or graphics. The number of features and graphics has little impact on frame render time, meaning it scales well, and pushes a constant GPU payload. However, rendering updates is CPU and system memory intensive, which can have an impact on device battery life.

How to use the sample

Use the 'Animated Zoom' button to trigger the same zoom animation on both static and dynamically maps.

How it works

  1. Create an ArcGISMap and set several loadSettings: preferred[Point/Polyline/Polygon]FeatureRenderingMode(...).
  2. The rendering mode can be set to Enums.FeatureRenderingModeStatic, Enums.FeatureRenderingModeDynamic or Enums.FeatureRenderingModeAutomatic.

    • In Static rendering mode, the number of features and graphics has little impact on frame render time, meaning it scales well, however points don't stay screen-aligned and point/polyline/polygon objects are only redrawn once map view navigation is complete.
    • In Dynamic rendering mode, large numbers of features or graphics can affect the responsiveness of maps or scenes to user interaction, however points remain screen-aligned and point/polyline/polygon objects are continually redrawn while the map view is navigating.
  3. When left to automatic rendering, points are drawn dynamically and polylines and polygons statically.

Relevant API

  • FeatureLayer
  • FeatureLayer.renderingMode
  • LoadSettings
  • Map
  • MapView

Tags

dynamic, feature layer, features, rendering, static

Sample Code

FeatureLayerRenderingModeMap.qml
                                                                                                                                                                                                          
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
// [WriteFile Name=FeatureLayerRenderingModeMap, Category=Layers]
// [Legal]
// Copyright 2017 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.12

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    property bool zoomedOut: true


    MapView {
        id: topMapView
        anchors {
            left: parent.left
            right: parent.right
            top: parent.top
        }
        height: parent.height / 2

        Map {
            // Set the preferred rendering mode to static
            LoadSettings {
                preferredPointFeatureRenderingMode: Enums.FeatureRenderingModeStatic
                preferredPolygonFeatureRenderingMode: Enums.FeatureRenderingModeStatic
                preferredPolylineFeatureRenderingMode: Enums.FeatureRenderingModeStatic
            }
            initialViewpoint: zoomOutViewpoint

            // Add the Feature Layers
            FeatureLayer {
                ServiceFeatureTable {
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/Energy/Geology/FeatureServer/0"
                }
            }

            FeatureLayer {
                ServiceFeatureTable {
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/Energy/Geology/FeatureServer/8"
                }
            }

            FeatureLayer {
                ServiceFeatureTable {
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/Energy/Geology/FeatureServer/9"
                }
            }
        }

        Rectangle {
            anchors {
                horizontalCenter: parent.horizontalCenter
                top: parent.top
                margins: 5
            }
            color: "white"
            radius: 5
            width: 200
            height: 30

            Text {
                anchors.centerIn: parent
                text: "Rendering Mode Static"
            }
        }
    }

    MapView {
        id: bottomMapView
        anchors {
            left: parent.left
            right: parent.right
            bottom: parent.bottom
        }
        height: parent.height / 2

        Map {
            // Set the preferred rendering mode to dynamic
            LoadSettings {
                preferredPointFeatureRenderingMode: Enums.FeatureRenderingModeDynamic
                preferredPolygonFeatureRenderingMode: Enums.FeatureRenderingModeDynamic
                preferredPolylineFeatureRenderingMode: Enums.FeatureRenderingModeDynamic
            }
            initialViewpoint: zoomOutViewpoint

            // Add the Feature Layers
            FeatureLayer {
                ServiceFeatureTable {
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/Energy/Geology/FeatureServer/0"
                }
            }

            FeatureLayer {
                ServiceFeatureTable {
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/Energy/Geology/FeatureServer/8"
                }
            }

            FeatureLayer {
                ServiceFeatureTable {
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/Energy/Geology/FeatureServer/9"
                }
            }
        }

        Rectangle {
            anchors {
                horizontalCenter: parent.horizontalCenter
                top: parent.top
                margins: 5
            }
            color: "white"
            radius: 5
            width: 200
            height: 30

            Text {
                anchors.centerIn: parent
                text: "Rendering Mode Dynamic"
            }
        }
    }

    ViewpointCenter {
        id: zoomOutViewpoint
        targetScale: 650000
        rotation: 0

        Point {
            x: -118.37
            y: 34.46
            spatialReference: SpatialReference { wkid: 4326 }
        }
    }

    ViewpointCenter {
        id: zoomInViewpoint
        targetScale: 50000
        rotation: 90

        Point {
            x: -118.45
            y: 34.395
            spatialReference: SpatialReference { wkid: 4326 }
        }
    }

    Button {
        anchors {
            left: parent.left
            top: parent.top
            margins: 10
        }
        property string startText: "Start Animation"
        property string stopText: "Stop Animation"
        text: startText
        onClicked: {
            if (text === startText) {
                timer.start();
                text = stopText;
            } else {
                timer.stop();
                text = startText;
            }
        }
    }

    Timer {
        id: timer
        interval: 7000
        repeat: true
        triggeredOnStart: true
        onTriggered: {
            let viewpoint;
            if (zoomedOut)
                viewpoint = zoomInViewpoint;
            else
                viewpoint = zoomOutViewpoint;
            topMapView.setViewpointAndSeconds(viewpoint, 5);
            bottomMapView.setViewpointAndSeconds(viewpoint, 5);
            zoomedOut = !zoomedOut;
        }
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.