Change atmosphere effect

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
// [WriteFile Name=ChangeAtmosphereEffect, Category=Scenes]
// [Legal]
// Copyright 2018 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import Esri.ArcGISRuntime

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    states: [
        State {
            when: noAtmosphereButton.checked
            PropertyChanges {
                target: sceneView
                atmosphereEffect: Enums.AtmosphereEffectNone
            }
        },
        State {
            when: realisticAtmosphereButton.checked
            PropertyChanges {
                target: sceneView
                atmosphereEffect: Enums.AtmosphereEffectRealistic
            }
        },
        State {
            when: horizonAtmosphereButton.checked
            PropertyChanges {
                target: sceneView
                atmosphereEffect: Enums.AtmosphereEffectHorizonOnly
            }
        }
    ]

    SceneView {
        id: sceneView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on SceneView to initially enable keyboard navigation
            forceActiveFocus();
            setViewpointCameraAndSeconds(camera, 0);
        }

        Camera {
            id: camera
            Point {
                y: 64.416919
                x: -14.483728
                z: 100
            }
            heading : 318
            pitch : 105
            roll: 0
        }

        Scene {
            id: scene
            Basemap {
                initStyle: Enums.BasemapStyleArcGISImageryStandard
            }

            Surface {
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }
        }
    }

    Rectangle {
        anchors {
            top: parent.top
            right: parent.right
            margins: 5
        }

        color: Qt.rgba(1, 1, 1, 0.3);
        width: childrenRect.width
        height: childrenRect.height
        ColumnLayout {
            id: layout

            Text {
                Layout.margins: 5
                color: "white"
                text: "Atmosphere effects"
            }

            Button {
                id: noAtmosphereButton
                Layout.margins: 5
                Layout.fillWidth: true
                text: "None"
                checkable: true
            }

            Button {
                id: realisticAtmosphereButton
                Layout.margins: 5
                Layout.fillWidth: true
                text: "Realistic"
                checkable: true
            }

            Button {
                id: horizonAtmosphereButton
                Layout.margins: 5
                Layout.fillWidth: true
                text: "Horizon only"
                checkable: true
                checked: true
            }
        }

        ButtonGroup {
            buttons: [noAtmosphereButton, realisticAtmosphereButton, horizonAtmosphereButton]
        }
    }
}