Symbolize a shapefile

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
// [WriteFile Name=SymbolizeShapefile, Category=DisplayInformation]
// [Legal]
// Copyright 2017 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import Esri.ArcGISRuntime
import Esri.ArcGISExtras

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property url dataPath: {
        Qt.platform.os === "ios" ?
                    System.writableLocationUrl(System.StandardPathsDocumentsLocation) + "/ArcGIS/Runtime/Data/shp/" :
                    System.writableLocationUrl(System.StandardPathsHomeLocation) + "/ArcGIS/Runtime/Data/shp/"
    }

    MapView {
        id: mapView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
        }

        Map {
            Basemap {
                initStyle: Enums.BasemapStyleArcGISStreets
            }

            // Declare a FeatureLayer for displaying the shapefile
            FeatureLayer {
                id: featureLayer
                // Create a ShapefileFeatureTable pointing to the data location
                ShapefileFeatureTable {
                    path: dataPath + "Subdivisions.shp"
                }
            }

            // set an initial viewpoint
            ViewpointCenter {
                Point {
                    y: 4818336
                    x: -11662054
                    spatialReference: SpatialReference { wkid: 3857 }
                }
                targetScale: 200000
            }
        }
    }

    // Update the renderer on click
    Button {
        anchors {
            left: parent.left
            top: parent.top
            margins: 10
        }
        text: "Change Renderer"
        onClicked: {
            // apply the new renderer
            featureLayer.renderer = simpleRenderer;
            visible = false;
        }
    }

    // Create a SimpleRenderer
    SimpleRenderer {
        id: simpleRenderer

        SimpleFillSymbol {
            color: "yellow"
            style: Enums.SimpleFillSymbolStyleSolid

            SimpleLineSymbol {
                color: "red"
                style: Enums.SimpleLineSymbolStyleSolid
                width: 1
            }
        }
    }
}