Scene symbols

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
// [WriteFile Name=Symbols, Category=Scenes]
// [Legal]
// Copyright 2016 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import Esri.ArcGISRuntime

Rectangle {
    width: 800
    height: 600

    readonly property double pointX: 44.975
    readonly property double pointY: 34
    readonly property double pointZ: 500

    // Create a scene view
    SceneView {
        anchors.fill: parent

        // create a scene...scene is a default property of sceneview
        // and thus will get added to the sceneview
        Scene {
            // add a basemap
            Basemap {
                initStyle: Enums.BasemapStyleArcGISImageryStandard
            }

            // add a surface...surface is a default property of scene
            Surface {
                // add an arcgis tiled elevation source...elevation source is a default property of surface
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }
        }

        // add a graphics overlay
        GraphicsOverlay {
            id: graphicsOverlay
            LayerSceneProperties {
                surfacePlacement: Enums.SurfacePlacementAbsolute
            }
        }

        Component.onCompleted: {
            // Set the focus on SceneView to initially enable keyboard navigation
            forceActiveFocus();

            // set viewpoint to the specified camera
            setViewpointCameraAndWait(camera);

            addSymbols();
        }
    }

    // create the camera to be used as the scene view's viewpoint
    Camera {
        id: camera
        location: Point {
            x: 45
            y: 34
            z: 6000
            spatialReference: SpatialReference { wkid: 4326 }
        }
        heading: 0
        pitch: 0
        roll: 0
    }

    // listmodel to store the symbol colors and styles
    ListModel {
        id: symbolModel

        ListElement {
            symbolStyle: Enums.SimpleMarkerSceneSymbolStyleCone
            color: "red"
        }
        ListElement {
            symbolStyle: Enums.SimpleMarkerSceneSymbolStyleCube
            color: "white"
        }
        ListElement {
            symbolStyle: Enums.SimpleMarkerSceneSymbolStyleCylinder
            color: "purple"
        }
        ListElement {
            symbolStyle: Enums.SimpleMarkerSceneSymbolStyleDiamond
            color: "turquoise"
        }
        ListElement {
            symbolStyle: Enums.SimpleMarkerSceneSymbolStyleSphere
            color: "blue"
        }
        ListElement {
            symbolStyle: Enums.SimpleMarkerSceneSymbolStyleTetrahedron
            color: "yellow"
        }
    }

    // function to dynamically create the graphics and add them to the graphics overlay
    function addSymbols() {
        for (let i = 0; i < symbolModel.count; i++) {
            const elem = symbolModel.get(i);

            // create a simple marker scene symbol
            const smss = ArcGISRuntimeEnvironment.createObject("SimpleMarkerSceneSymbol", {
                                                                   style: elem.symbolStyle,
                                                                   color: elem.color,
                                                                   width: 200,
                                                                   height: 200,
                                                                   depth: 200,
                                                                   anchorPosition: Enums.SceneSymbolAnchorPositionCenter
                                                               });

            // create a new point geometry
            const point = ArcGISRuntimeEnvironment.createObject("Point", {
                                                                    x: pointX + 0.01 * i,
                                                                    y: pointY,
                                                                    z: pointZ,
                                                                    spatialReference: Factory.SpatialReference.createWgs84()
                                                                });

            // create a graphic using the point and the symbol
            const graphic = ArcGISRuntimeEnvironment.createObject("Graphic", {
                                                                      geometry: point,
                                                                      symbol: smss
                                                                  });

            // add the graphic to the graphics overlay
            graphicsOverlay.graphics.append(graphic);
        }
    }
}