Query map image sublayer

View inQMLC++
View on GitHub
Sample viewer app

Find features in a sublayer based on attributes and location.

screenshot

Use case

Sublayers of an ArcGISMapImageLayer may expose a ServiceFeatureTable through a table property. This allows you to perform the same queries available when working with a table from a FeatureLayer: attribute query, spatial query, statistics query, query for related features, etc. An image layer with a sublayer of counties can be queried by population to only show those above a minimum population.

How to use the sample

Specify a minimum population in the input field (values under 1810000 will produce a selection in all layers) and click the query button to query the sublayers in the current view extent. After a short time, the results for each sublayer will appear as graphics.

How it works

  1. Create an ArcGISMapImageLayer object using the URL of an image service.
  2. After loading the layer, get the sublayer you want to query with (ArcGISMapImageSublayer) layer.mapImageSublayers.get(index).
  3. Load the sublayer, and then get its ServiceFeatureTable with sublayer.table.
  4. Create QueryParameters. You can use queryParameters.whereClause = sqlQueryString to query against a table attribute and/or set queryParameters.geometry = extent to limit the results to an area of the map.
  5. Call sublayerTable.queryFeatures(queryParameters) to get a FeatureQueryResult with features matching the query. The result is an iterable of features.

Relevant API

  • ArcGISMapImageLayer
  • ArcGISMapImageLayer.loadTablesAndLayers
  • ArcGISMapImageSublayer
  • ArcGISMapImageSublayer.table
  • QueryParameters
  • ServiceFeatureTable

Additional information

An ArcGISMapImageSublayer must be loaded before accessing its metadata or table. Use ArcGISMapImageLayer.loadTablesAndLayers to recursively load all sublayers and tables associated with a map image layer. Some sublayers do not have an associated table (group layers, for example) and some may not support specific types of queries. Consult the map service metadata for details.

Tags

MapServer, Query, Sublayer, Table

Sample Code

QueryMapImageSublayer.qml
                                                                                                                                                                                                                              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
// [WriteFile Name=QueryMapImageSublayer, Category=Layers]
// [Legal]
// Copyright 2018 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.12

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    property var citiesTable
    property var  statesTable
    property var  countiesTable

    // Declare a MapView
    MapView {
        id: mapView
        anchors.fill: parent

        // Desclare a Map inside the MapView
        Map {
            // Declare a Basemap
            Basemap {
                initStyle: Enums.BasemapStyleArcGISStreets
            }

            // Add a Map Image Layer
            ArcGISMapImageLayer {
                url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/USA/MapServer"

                // Once the layer loads, load the tables and sublayers
                onLoadStatusChanged: {
                    if (loadStatus !== Enums.LoadStatusLoaded)
                        return;

                    loadTablesAndLayers();
                }

                // Once tables and sublayers load, obtain the tables and connect signals
                onLoadTablesAndLayersStatusChanged: {
                    if (loadTablesAndLayersStatus !== Enums.TaskStatusCompleted)
                        return;

                    if (mapImageSublayers.count < 4)
                        return;

                    // get the sublayer's tables
                    citiesTable = mapImageSublayers.get(0).table;
                    statesTable = mapImageSublayers.get(2).table;
                    countiesTable = mapImageSublayers.get(3).table;

                    // connect to city sublayer query signal
                    citiesTable.queryFeaturesStatusChanged.connect(()=> {
                        if (citiesTable.queryFeaturesStatus !== Enums.TaskStatusCompleted)
                            return;

                        // add the results as graphics
                        addResultsAsGraphics(citiesTable.queryFeaturesResult, citySymbol);
                    });

                    // connect to county sublayer query signal
                    countiesTable.queryFeaturesStatusChanged.connect(()=> {
                        if (countiesTable.queryFeaturesStatus !== Enums.TaskStatusCompleted)
                            return;

                        // add the results as graphics
                        addResultsAsGraphics(countiesTable.queryFeaturesResult, countyFillSymbol);
                    });

                    // connect to state sublayer query signal
                    statesTable.queryFeaturesStatusChanged.connect(()=> {
                        if (statesTable.queryFeaturesStatus !== Enums.TaskStatusCompleted)
                            return;

                        // add the results as graphics
                        addResultsAsGraphics(statesTable.queryFeaturesResult, stateFillSymbol);
                    });
                }
            }

            // set an initial viewpoint
            ViewpointCenter {
                targetScale: 6000000
                Point {
                    x: -12716000.00
                    y: 4170400.00
                    spatialReference: SpatialReference { wkid: 3857 }
                }
            }
        }

        // Add a graphics overlay to show selected features
        GraphicsOverlay {
            id: selectedFeaturesOverlay
        }
    }

    function addResultsAsGraphics(results, symbol) {
        // get the iterator of features
        const iter = results.iterator;
        // add a graphic for each feature in the result
        while (iter.hasNext) {
            const feat = iter.next();
            const graphic = ArcGISRuntimeEnvironment.createObject("Graphic",
                                                                  {
                                                                      geometry: feat.geometry,
                                                                      symbol: symbol
                                                                  });
            selectedFeaturesOverlay.graphics.append(graphic);
        }
    }

    Rectangle {
        anchors {
            fill: controlColumn
            margins: -5
        }
        color: "#efefef"
        radius: 5
        border {
            color: "darkgray"
            width: 1
        }
    }

    Column {
        id: controlColumn
        anchors {
            left: parent.left
            top: parent.top
            margins: 10
        }
        spacing: 5

        Row {
            spacing: 5
            Text {
                id: fieldText
                anchors.verticalCenter: parent.verticalCenter
                text: "POP2000 >"
            }

            TextField {
                id: populationText
                anchors.verticalCenter: parent.verticalCenter
                width: 100
                text: "1100000"
                selectByMouse: true
                validator: IntValidator{}
            }
        }

        Button {
            anchors.horizontalCenter: parent.horizontalCenter
            text: "Query in extent"
            onClicked: {
                if (!citiesTable || !countiesTable || !statesTable)
                    return;

                selectedFeaturesOverlay.graphics.clear();

                // create the parameters
                const queryParams = ArcGISRuntimeEnvironment.createObject("QueryParameters",
                                                                          {
                                                                              whereClause: fieldText.text + populationText.text,
                                                                              geometry: mapView.currentViewpointExtent.extent
                                                                          });

                // query the feature tables
                citiesTable.queryFeatures(queryParams);
                countiesTable.queryFeatures(queryParams);
                statesTable.queryFeatures(queryParams);
            }
        }
    }

    SimpleMarkerSymbol {
        id: citySymbol
        color: "red"
        size: 16
        style: Enums.SimpleMarkerSymbolStyleCircle
    }

    SimpleFillSymbol {
        id: countyFillSymbol
        style: Enums.SimpleFillSymbolStyleDiagonalCross
        color: "cyan"

        SimpleLineSymbol {
            style: Enums.SimpleLineSymbolStyleDash
            color: "cyan"
            width: 2
        }
    }

    SimpleFillSymbol {
        id: stateFillSymbol
        color: "transparent"

        SimpleLineSymbol {
            id: stateLineSymbol
            color: "darkcyan"
            width: 6
        }
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.