Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Change atmosphere effect

Sample Viewer View Sample on GitHub

Changes the appearance of the atmosphere in a scene.

How to use the sample

Select one of the three available atmosphere effects. The sky will change to display the selected atmosphere effect.

How it works

  1. Create a Scene and display it in a SceneQuickView.
  2. Change the atmosphere effect with SceneView.atmosphereEffect.

Relevant API

  • Scene
  • AtmosphereEffect
  • SceneView

Additional Information

There are three atmosphere effect options:

  • None - No atmosphere effect. The sky is rendered black with a starfield consisting of randomly placed white dots.
  • Realistic - Atmosphere effect applied to both the sky and the surface as viewed from above.
  • Horizon only - Atmosphere effect applied to the sky (horizon) only. This is the default.

Tags

atmosphere, horizon, sky

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import QtQuick.Layouts 1.3
import Esri.ArcGISRuntime 100.9

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    states: [
        State {
            when: noAtmosphereButton.checked
            PropertyChanges {
                target: sceneView
                atmosphereEffect: Enums.AtmosphereEffectNone
            }
        },
        State {
            when: realisticAtmosphereButton.checked
            PropertyChanges {
                target: sceneView
                atmosphereEffect: Enums.AtmosphereEffectRealistic
            }
        },
        State {
            when: horizonAtmosphereButton.checked
            PropertyChanges {
                target: sceneView
                atmosphereEffect: Enums.AtmosphereEffectHorizonOnly
            }
        }
    ]

    SceneView {
        id: sceneView
        anchors.fill: parent

        Component.onCompleted: {
            setViewpointCameraAndSeconds(camera, 0);
        }

        Camera {
            id: camera
            Point {
                y: 64.416919
                x: -14.483728
                z: 100
            }
            heading : 318
            pitch : 105
            roll: 0
        }

        Scene {
            id: scene
            BasemapImagery {}

            Surface {
                ArcGISTiledElevationSource {
                    url: "http://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }
        }
    }

    Rectangle {
        anchors {
            top: parent.top
            right: parent.right
            margins: 5
        }

        color: Qt.rgba(1, 1, 1, 0.3);
        width: childrenRect.width
        height: childrenRect.height
        ColumnLayout {
            id: layout

            Text {
                Layout.margins: 5
                color: "white"
                text: "Atmosphere effects"
            }

            Button {
                id: noAtmosphereButton
                Layout.margins: 5
                Layout.fillWidth: true
                text: "None"
                checkable: true
            }

            Button {
                id: realisticAtmosphereButton
                Layout.margins: 5
                Layout.fillWidth: true
                text: "Realistic"
                checkable: true
            }

            Button {
                id: horizonAtmosphereButton
                Layout.margins: 5
                Layout.fillWidth: true
                text: "Horizon only"
                checkable: true
                checked: true
            }
        }

        ButtonGroup {
            buttons: [noAtmosphereButton, realisticAtmosphereButton, horizonAtmosphereButton]
        }
    }
}