Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Integrated windows authentication

Sample Viewer View Sample on GitHub

Uses Windows credentials to access services hosted on a portal secured with Integrated Windows Authentication (IWA).

Use case

IWA, which is built into Microsoft Internet Information Server (IIS), works well for intranet applications, but isn't always practical for internet apps.

How to use the sample

  • Search Public

    Click the "Search Public" button. This will anonymously connect to www.arcgis.com and will search for web maps stored on the portal. It will then populate the combo box with the results found from the portal. Select a web map item and click the "load web map" button to display it in the map view.

  • Search Secure

    Enter the URL(e.g. https://myorgiwaportal.myorg.com/gis) to your IWA-secured portal in the text field at the top of the screen. Click the "Search Secure". You will be prompted for a username (including domain, such as username@DOMAIN or domain\username), and password. On Windows it will automatically use your current login credentials. If you authenticate successfully, portal item results will display in the combo box below. Select a web map item and click the "load web map" button to display it in the map view.

How it works

  1. Declare an AuthenticationView and connect the AuthenticationManager to it.
  2. The authentication manager object is configured with a challenge handler that will prompt for a Windows login (username and password) if a secure resource is encountered.
  3. When a search for portal items is performed against an IWA-secured portal, the challenge handler creates an UserCredential object from the information entered by the user or what was automatically obtained by the current Windows login.
  4. If the user authenticates, the search returns a list of web maps from PortalItem objects and the user can select one to display as an Map.

Relevant API

  • AuthenticationManager
  • Portal
  • UserCredential

About the data

This sample searches for web map portal items on a secure portal. To successfully run the sample, you need:

  • Access to a portal secured with Integrated Windows Authentication that contains one or more web map items.
  • A login that grants you access to the portal.

Additional information

More information about IWA and its use with ArcGIS can be found at the following links:

Tags

authentication, security, windows

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.12
import QtQuick.Layouts 1.12
import Esri.ArcGISRuntime 100.9
import Esri.ArcGISRuntime.Toolkit.Dialogs 100.9

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property url arcgis_url: "https://www.arcgis.com"
    property var portalItem
    property var iwaSecurePortal

    MapView {
        id: mapView
        anchors.fill: parent

        Map {
            BasemapTopographic {}
        }
    }

    Portal {
        id: publicPortal
        url: arcgis_url
        onLoadStatusChanged: {
            if (loadStatus === Enums.LoadStatusFailedToLoad) {
                webMapMsg.text = loadError.message;
                webMapMsg.visible = true;
                indicator.running = false;
                return;
            }

            if (loadStatus === Enums.LoadStatusLoaded){
                findItems(webmapQuery);
                return;
            }
        }

        onFindItemsStatusChanged: {
            if ( findItemsStatus === Enums.TaskStatusCompleted ) {
                indicator.running = false;
                webmapsList.textRole = "title";
                webmapsList.model = findItemsResult.itemResults;
            }
        }

    }

    Rectangle {
        id: portalLayoutRect
        anchors {
            margins: 5
            left: parent.left
            top: parent.top
        }
        width: childrenRect.width
        height: childrenRect.height
        color: "#000000"
        opacity: .70
        radius: 5

        ColumnLayout {
            TextField {
                id: securePortalUrl
                Layout.fillWidth: true
                Layout.margins: 2
                placeholderText: qsTr("Enter portal url secured by IWA")
                selectByMouse: true
                background: Rectangle {
                    implicitWidth: parent.width
                    implicitHeight: parent.height
                    color: "white"
                }
            }

            Row {
                id: myRow
                Layout.alignment: Qt.AlignHCenter | Qt.AlignVCenter
                Layout.margins: 2
                spacing: 3

                Button {
                    text: qsTr("Search Public")
                    onClicked: {
                        if (publicPortal.loadStatus !== Enums.LoadStatusLoaded) {
                            indicator.running = true;
                            publicPortal.load();
                        } else {
                            publicPortal.findItems(webmapQuery);
                        }
                    }
                }
                Button {
                    text: qsTr("Search Secure")
                    onClicked: {
                        if (securePortalUrl.text) {
                            searchPortal(securePortalUrl.text);
                        } else {
                            webMapMsg.text = "Portal URL is empty. Please enter a portal URL"
                            webMapMsg.visible = true;
                            return;
                        }
                    }
                }
            }

            ComboBox {
                id: webmapsList
                Layout.margins: 2
                Layout.fillWidth: true
            }

            Button {
                text: qsTr("Load Web Map")
                Layout.fillWidth: true
                Layout.margins: 2
                enabled: webmapsList.model ? true : false
                onClicked: loadSelectedWebmap(webmapsList.model.get(webmapsList.currentIndex));
            }
        }
    }

    BusyIndicator {
        id: indicator
        anchors.centerIn: parent
        running: false
    }

    PortalQueryParametersForItems {
        id: webmapQuery
        types: [ Enums.PortalItemTypeWebMap ]
    }

    function searchPortal (portalUrl) {

        if (!iwaSecurePortal) {
            iwaSecurePortal = ArcGISRuntimeEnvironment.createObject("Portal", {url: portalUrl});
        } else if (iwaSecurePortal && (iwaSecurePortal.loadStatus === Enums.LoadStatusFailedToLoad)) {
            iwaSecurePortal = ArcGISRuntimeEnvironment.createObject("Portal", {url: portalUrl});
        } else if (iwaSecurePortal && (iwaSecurePortal.loadStatus === Enums.LoadStatusLoaded)) {
            if (iwaSecurePortal.url != portalUrl) {
                iwaSecurePortal = ArcGISRuntimeEnvironment.createObject("Portal", {url: portalUrl});
            } else {
                indicator.running = true;
                iwaSecurePortal.findItems(webmapQuery);
                return;
            }
        }

        iwaSecurePortal.loadStatusChanged.connect(()=> {
            if (iwaSecurePortal.loadStatus === Enums.LoadStatusFailedToLoad) {
                webMapMsg.text = iwaSecurePortal.loadError.message;
                webmapsList.model = null;
                webMapMsg.visible = true;
                indicator.running = false;
                return;
            }

            if (iwaSecurePortal.loadStatus === Enums.LoadStatusLoaded){
                iwaSecurePortal.findItems(webmapQuery);
                return;
            }

        });

        iwaSecurePortal.findItemsStatusChanged.connect(()=> {
            if ( iwaSecurePortal.findItemsStatus === Enums.TaskStatusCompleted ) {
                indicator.running = false;
                webmapsList.textRole = "title";
                webmapsList.model = iwaSecurePortal.findItemsResult.itemResults;
            }
        });

        iwaSecurePortal.load();
        indicator.running = true;
    }

    function loadSelectedWebmap(selectedWebmap) {
        mapView.map = ArcGISRuntimeEnvironment.createObject("Map", {"item": selectedWebmap});
    }

    // Uncomment this section when running as standalone application
    /*
    AuthenticationView {
        authenticationManager: AuthenticationManager
    }*/

    Dialog {
        id: webMapMsg
        property alias text : textLabel.text
        modal: true
        x: Math.round(parent.width - width) / 2
        y: Math.round(parent.height - height) / 2
        standardButtons: Dialog.Ok
        title: qsTr("Could not load web map!")
        Text {
            id: textLabel
        }
        onAccepted: visible = false;
    }
}