Play a KML tour

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
// [WriteFile Name=PlayAKmlTour, Category=Layers]
// [Legal]
// Copyright 2019 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import Esri.ArcGISRuntime
import Esri.ArcGISExtras

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property url dataPath: {
        Qt.platform.os === "ios" ?
                    System.writableLocationUrl(System.StandardPathsDocumentsLocation) + "/ArcGIS/Runtime/Data" :
                    System.writableLocationUrl(System.StandardPathsHomeLocation) + "/ArcGIS/Runtime/Data"
    }

    SceneView {
        id: sceneView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on SceneView to initially enable keyboard navigation
            forceActiveFocus();
        }

        Scene {
            id: scene
            Basemap {
                initStyle: Enums.BasemapStyleArcGISImageryStandard
            }

            Surface {
                ArcGISTiledElevationSource {
                    url: "https://elevation3d.arcgis.com/arcgis/rest/services/WorldElevation3D/Terrain3D/ImageServer"
                }
            }

            KmlLayer {
               dataset: KmlDataset {
                   id: kmlDataset
                   url: dataPath + "/kml/Esri_tour.kmz"
               }
               onLoadStatusChanged: {
                   if (loadStatus !== Enums.LoadStatusLoaded)
                       return;

                   const kmlTour = findFirstKMLTour(kmlDataset.rootNodes)

                   if (kmlTour !== null) {
                       kmlTour.tourStatusChanged.connect(()=> {
                           switch(kmlTour.tourStatus) {
                           case Enums.KmlTourStatusCompleted:
                           case Enums.KmlTourStatusInitialized:
                               playButton.enabled = true;
                               pauseButton.enabled = false;
                               resetButton.enabled = true;
                               break;
                           case Enums.KmlTourStatusPaused:
                               playButton.enabled = true;
                               pauseButton.enabled = false;
                               resetButton.enabled = true;
                               break;
                           case Enums.KmlTourStatusPlaying:
                               playButton.enabled = false;
                               pauseButton.enabled = true;
                               resetButton.enabled = true;
                               break;
                           case Enums.KmlTourStatusInitializing:
                           case Enums.KmlTourStatusNotInitialized:
                               break;
                           default:
                               break;
                           }
                       });
                       kmlTourController.tour = kmlTour;
                   }
               }

               Component.onDestruction: {
                   kmlTourController.tour = null;
               }
            }

            KmlTourController {
                id: kmlTourController
            }
        }

        Rectangle {
            id: buttonBackground
            anchors {
                left: parent.left
                top: parent.top
                margins: 3
            }
            width: childrenRect.width
            height: childrenRect.height
            color: "#000000"
            opacity: .75
            radius: 5

            // catch mouse signals from propagating to parent
            MouseArea {
                anchors.fill: parent
                onClicked: mouse => mouse.accepted = true
                onWheel: wheel => wheel.accepted = true
            }

            RowLayout {
                spacing: 0
                Button {
                    id: playButton
                    text: qsTr("Play")
                    Layout.margins: 2
                    enabled: false
                    onClicked: kmlTourController.play();
                }

                Button {
                    id: pauseButton
                    text: qsTr("Pause")
                    Layout.margins: 2
                    enabled: false
                    onClicked: kmlTourController.pause();
                }

                Button {
                    id: resetButton
                    text: qsTr("Reset")
                    Layout.margins: 2
                    enabled: false
                    onClicked: kmlTourController.reset();
                }
            }
        }
    }

    function findFirstKMLTour(nodes) {
        for (let i = 0; i < nodes.length; i++) {
            const node = nodes[i];
            if (node.kmlNodeType === Enums.KmlNodeTypeKmlTour)
                return node;
            else if ((node.kmlNodeType === Enums.KmlNodeTypeKmlFolder) || (node.kmlNodeType === Enums.KmlNodeTypeKmlDocument))
                return findFirstKMLTourFromListModel(node.childNodesListModel);
        }
        return null;
    }

    function findFirstKMLTourFromListModel(nodes) {
        for (let i = 0; i < nodes.count; ++i) {
            const node = nodes.get(i);
            if (node.kmlNodeType === Enums.KmlNodeTypeKmlTour)
                return node;
            else if ((node.kmlNodeType === Enums.KmlNodeTypeKmlFolder) || (node.kmlNodeType === Enums.KmlNodeTypeKmlDocument))
                return findFirstKMLTourFromListModel(node.childNodesListModel);
        }
        return null;
    }
}