Skip To Content ArcGIS for Developers Sign In Dashboard

ArcGIS Runtime SDK for Qt

Service feature table (manual cache)

Sample Viewer View Sample on GitHub

Display a feature layer from a service using the manual cache feature request mode.

Use case

ServiceFeatureTable supports three request modes, which define how features are requested from the service and stored in the local table. The feature request modes have different performance characteristics. Use manual cache in scenarios where you want to explicitly control requests for features. See Table performance concepts to learn more.

How to use the sample

Run the sample and pan and zoom around the map. No features will be requested and displayed automatically. Press the Populate button, and features will display.

How it works

  1. Set the ServiceFeatureTable.featureRequestMode property of the service feature table to Enums.FeatureRequestModeManualCache before the table is loaded.
  2. Load the table.
  3. Call populateFromService on the table to request features.

Relevant API

  • Enums.FeatureRequestModeManualCache
  • FeatureLayer
  • ServiceFeatureTable
  • ServiceFeatureTable.featureRequestMode
  • ServiceFeatureTable.populateFromService

About the data

The samples uses an incident feature layer queried to show tree maintenance or damage. The sample opens with an initial visible extent centered over San Francisco.

Additional information

In manual cache mode, features are never automatically populated from the service. All features are loaded manually using calls to populateFromService.

Tags

cache, feature request mode, performance

Sample Code

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.9

Rectangle {
    width: 800
    height: 600

    

    // Map view UI presentation at top
    MapView {
        id: mv

        anchors.fill: parent
        wrapAroundMode: Enums.WrapAroundModeDisabled

        Map {
            BasemapTopographic {}
            initialViewpoint: viewPoint

            FeatureLayer {
                id: featureLayer

                ServiceFeatureTable {
                    id: featureTable
                    url: "https://sampleserver6.arcgisonline.com/arcgis/rest/services/SF311/FeatureServer/0"
                    featureRequestMode: Enums.FeatureRequestModeManualCache

                    onPopulateFromServiceStatusChanged: {
                        if (populateFromServiceStatus === Enums.TaskStatusCompleted) {
                            if (!populateFromServiceResult.iterator.hasNext) {
                                return;
                            }

                            const count = populateFromServiceResult.iterator.features.length;
                            console.log("Retrieved %1 features".arg(count));
                        }
                    }
                }
            }
        }

        ViewpointCenter {
            id: viewPoint
            center: Point {
                x: -13630484
                y: 4545415
                spatialReference: SpatialReference {
                    wkid: 102100
                }
            }
            targetScale: 300000
        }
    }

    QueryParameters {
        id: params
        whereClause: "req_Type = \'Tree Maintenance or Damage\'"
    }

    Row {
        anchors {
            bottom: parent.bottom
            left: parent.left
            right: parent.right
            margins: 5
            bottomMargin: 25
        }
        spacing: 5

        // button to populate from service
        Button {
            text: "Populate"
            enabled: featureTable.loadStatus === Enums.LoadStatusLoaded
            onClicked: {
                featureTable.populateFromService(params, true, ["*"]);
            }
        }
    }
}