Apply scheduled updates to preplanned map area

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
// [WriteFile Name=ApplyScheduledMapUpdates, Category=Maps]
// [Legal]
// Copyright 2019 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick
import QtQuick.Controls
import Esri.ArcGISRuntime
import Esri.ArcGISExtras

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    readonly property string tempDataPath: System.temporaryFolder.path + "/" + new Date().getTime()
    readonly property url origMmpkPath: {
        Qt.platform.os === "ios" ?
                    System.writableLocationUrl(System.StandardPathsDocumentsLocation) +  "/ArcGIS/Runtime/Data/mmpk/canyonlands/canyonlands.zip" :
                    System.writableLocationUrl(System.StandardPathsHomeLocation) +  "/ArcGIS/Runtime/Data/mmpk/canyonlands/canyonlands.zip"
    }
    readonly property string destMmpkPath: tempDataPath + "/canyonlands.zip"
    property MobileMapPackage mmpk

    // For the purposes of demonstrating the sample,
    // create a temporary copy of the local offline map files,
    // so that updating does not overwrite them permanently
    Component.onCompleted: {
        // copy the zip
        fileFolder.makePath(tempDataPath)
        fileFolder.copyFile(origMmpkPath, destMmpkPath);

        // unzip the archive
        zipArchive.extractAll(tempDataPath + "/canyonlands")
    }

    function createMmpk() {
        mmpk = ArcGISRuntimeEnvironment.createObject("MobileMapPackage", {
                                                         path: System.resolvedPathUrl(tempDataPath + "/canyonlands")
                                                     });
        mmpk.loadStatusChanged.connect(()=> {
                                           if (mmpk.loadStatus === Enums.LoadStatusLoaded) {
                                               // check size of maps
                                               if (mmpk.maps.length === 0)
                                                   return;

                                               // get map from mmpk
                                               const map = mmpk.maps[0];

                                               // set on the mapview for display
                                               mapView.map = map;

                                               // hook up to offline map task
                                               offlineMapSyncTask.map = map;

                                               // check for updates
                                               offlineMapSyncTask.checkForUpdates();
                                           } else if (mmpk.loadStatus === Enums.LoadStatusFailedToLoad) {
                                               console.log("failed to load", mmpk.error.message, mmpk.error.additionalMessage);
                                           }
                                       });

        mmpk.load();
    }

    MapView {
        id: mapView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
        }
    }

    OfflineMapSyncTask {
        id: offlineMapSyncTask

        property var syncJob

        onCheckForUpdatesStatusChanged: {
            if (checkForUpdatesStatus === Enums.TaskStatusInProgress) {
                console.log("Check for updates in progress...");
            } else if (checkForUpdatesStatus === Enums.TaskStatusErrored) {
                console.log("Check for updates error:", error.message, error.additionalMessage);
            } else if (checkForUpdatesStatus === Enums.TaskStatusCompleted) {
                console.log("Check for updates complete");

                // if updates are available, enable the download button & set detail text
                if (checkForUpdatesResult.downloadAvailability === Enums.OfflineUpdateAvailabilityAvailable) {
                    // enable the button
                    downloadUpdatesButton.enabled = true;

                    // set the text
                    availabilityText.text = "Updates Available";
                    availabilityDetailsText.text = "Updates size: %1 bytes".arg(offlineMapSyncTask.checkForUpdatesResult.scheduledUpdatesDownloadSize);
                } else {
                    // disable the button
                    downloadUpdatesButton.enabled = false;

                    // set the text
                    availabilityText.text = "No updates available";
                    availabilityDetailsText.text = "The preplanned map area is up to date"
                }

                busyIndicator.visible = false;
            }
        }

        onCreateDefaultOfflineMapSyncParametersStatusChanged: {
            if (createDefaultOfflineMapSyncParametersStatus === Enums.TaskStatusInProgress) {
                console.log("Create Parameters in progress...");
            } else if (createDefaultOfflineMapSyncParametersStatus === Enums.TaskStatusErrored) {
                console.log("Create Parameters error:", error.message, error.additionalMessage);
            } else if (createDefaultOfflineMapSyncParametersStatus === Enums.TaskStatusCompleted) {
                console.log("Create Parameters complete");

                // get the parameters result
                const params = createDefaultOfflineMapSyncParametersResult;

                // set the parameters to download all updates for the mobile map packages
                params.preplannedScheduledUpdatesOption = Enums.PreplannedScheduledUpdatesOptionDownloadAllUpdates;

                // create the job
                syncJob = offlineMapSyncTask.syncOfflineMap(createDefaultOfflineMapSyncParametersResult);
                var jobStatus = syncJob.jobStatus;

                // connect to the job signals
                syncJob.statusChanged.connect((jobStatus)=> {
                                                     if (jobStatus === Enums.JobStatusSucceeded) {
                                                         const mapResult = syncJob.result;

                                                         if (mapResult.mobileMapPackageReopenRequired) {
                                                             // close and reopen the MMPK if required
                                                             mmpk.close();
                                                             createMmpk();
                                                         } else {
                                                             console.log("not required");
                                                         }
                                                         busyIndicator.visible = false;

                                                         // re-check if updates are available
                                                         offlineMapSyncTask.checkForUpdates();
                                                     } else if (jobStatus === Enums.JobStatusFailed) {
                                                         console.log("sync job failed");
                                                         busyIndicator.visible = false;
                                                     }
                                                 });

                // start the job
                syncJob.start();
            }
        }
    }

    Rectangle {
        anchors.fill: controlColumn
        anchors.margins: -5
        color: "#404040"
    }

    Column {
        id: controlColumn
        anchors {
            left: parent.left
            top: parent.top
            margins: 10
        }
        spacing: 5

        Button {
            id: downloadUpdatesButton
            text: "Apply Scheduled Updates"
            enabled: false

            onClicked: {
                busyIndicator.visible = true;
                offlineMapSyncTask.createDefaultOfflineMapSyncParameters();
            }
        }

        Text {
            id: availabilityText
            color: "white"
        }

        Text {
            id: availabilityDetailsText
            color: "white"
        }
    }

    ZipArchive {
        id: zipArchive
        path: destMmpkPath

        onExtractCompleted: {
            // create the mmpk once the zip archive is copied
            createMmpk();
        }
    }

    FileFolder {
        id: fileFolder
    }

    BusyIndicator {
        id: busyIndicator
        anchors.centerIn: parent
    }
}