Configure subnetwork trace

View inQMLC++
View on GitHub
Sample viewer app

Get a server-defined trace configuration for a given tier and modify its traversability scope, add new condition barriers and control what is included in the subnetwork trace result.

screenshot

Use case

While some traces are built from an ad-hoc group of parameters, many are based on a variation of the trace configuration taken from the subnetwork definition. For example, an electrical trace will be based on the trace configuration of the subnetwork, but may add additional clauses to constrain the trace along a single phase. Similarly, a trace in a gas or electric design application may include features with a status of "In Design" that are normally excluded from trace results.

How to use the sample

The sample loads with a server-defined trace configuration from a tier. Check or uncheck which options to include in the trace - such as containers or barriers. Use the selection boxes to define a new condition network attribute comparison, and then use 'Add' to add the it to the trace configuration. Click 'Trace' to run a subnetwork trace with this modified configuration from a default starting location.

Example barrier conditions for the default dataset:

  • 'Transformer Load' Equal '15'
  • 'Phases Current' DoesNotIncludeTheValues 'A'
  • 'Generation KW' LessThan '50'

How it works

  1. Create and load a UtilityNetwork with a feature service URL, then get an asset type and a tier by their names.
  2. Populate the choice list for the comparison source with the non-system defined Definition::networkAttributes. Populate the choice list for the comparison operator with the enum values from UtilityAttributeComparisonOperator.
  3. Create a UtilityElement from this asset type to use as the starting location for the trace.
  4. Update the selected barrier expression and the checked options in the UI using this tier's TraceConfiguration.
  5. When 'Network Attribute' is selected, if its Domain is a CodedValueDomain, populate the choice list for the comparison value with its CodedValues. Otherwise, display a free-form textbox for entering an attribute value.
  6. When 'Add' is clicked, create a new UtilityNetworkAttributeComparison using the selected comparison source, operator, and selected or typed value. Use the selected source's NetworkAttribute::dataType to convert the comparison value to the correct data type.
  7. If the Traversability's list of Barriers is not empty, create a UtilityTraceOrCondition with the existing Barriers and the new comparison from Step 6.
  8. When 'Trace' is clicked, create UtilityTraceParameters passing in UtilityTraceType::subnetwork and the default starting location. Set its TraceConfiguration with the modified options, selections, and expression; then run a UtilityNetwork::trace.
  9. When Reset is clicked, set the trace configurations expression back to its original value.
  10. Display the count of returned UtilityElementTraceResult::elements.

Relevant API

  • CodedValueDomain
  • UtilityAssetType
  • UtilityAttributeComparisonOperator
  • UtilityCategory
  • UtilityCategoryComparison
  • UtilityCategoryComparisonOperator
  • UtilityDomainNetwork
  • UtilityElement
  • UtilityElementTraceResult
  • UtilityNetwork
  • UtilityNetworkAttribute
  • UtilityNetworkAttributeComparison
  • UtilityNetworkDefinition
  • UtilityTerminal
  • UtilityTier
  • UtilityTraceAndCondition
  • UtilityTraceConfiguration
  • UtilityTraceOrCondition
  • UtilityTraceParameters
  • UtilityTraceResult
  • UtilityTraceType
  • UtilityTraversability

About the data

The Naperville electrical network feature service, hosted on ArcGIS Online, contains a utility network used to run the subnetwork-based trace shown in this sample.

Additional information

Using utility network on ArcGIS Enterprise 10.8 requires an ArcGIS Enterprise member account licensed with the Utility Network user type extension. Please refer to the utility network services documentation.

Credentials:

  • Username: viewer01
  • Password: I68VGU^nMurF

Tags

category comparison, condition barriers, network analysis, network attribute comparison, subnetwork trace, trace configuration, traversability, utility network, validate consistency

Sample Code

ConfigureSubnetworkTrace.qmlConfigureSubnetworkTrace.cppConfigureSubnetworkTrace.h
                                                                                                                                                                                                                    
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
// [WriteFile Name=ConfigureSubnetworkTrace, Category=UtilityNetwork]
// [Legal]
// Copyright 2020 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import QtQuick.Controls 2.12
import QtQuick.Layouts 1.12
import QtQuick.Shapes 1.12
import Esri.Samples 1.0

Item {
    readonly property var comparisonOperatorModel: ["Equal","NotEqual","GreaterThan","GreaterThanEqual","LessThan","LessThanEqual","IncludesTheValues","DoesNotIncludeTheValues","IncludesAny","DoesNotIncludeAny"]

    Rectangle {
        id: rootRectangle
        anchors.fill: parent
        color: "lightgrey"

        ScrollView {
            id: scrollView
            anchors.fill: parent

            ColumnLayout {
                id: controlItemsLayout
                anchors.left: parent.left
                anchors.right: parent.right

                CheckBox {
                    text: qsTr("Include barriers")
                    Layout.fillWidth: true
                    enabled: !busyIndicator.visible
                    checkState: Qt.Checked
                    onCheckStateChanged: model.changeIncludeBarriersState(checked);
                }

                CheckBox {
                    text: qsTr("Include containers")
                    Layout.fillWidth: true
                    enabled: !busyIndicator.visible
                    checkState: Qt.Checked
                    onCheckStateChanged: model.changeIncludeContainersState(checked);
                }

                Shape {
                    height: 2
                    ShapePath {
                        strokeWidth: 1
                        strokeColor: "black"
                        strokeStyle: ShapePath.SolidLine
                        startX: 2; startY: 0
                        PathLine { x: controlItemsLayout.width - 2 ; y: 0 }
                    }
                }

                Text {
                    text: qsTr("Example barrier condition for this data. 'Transformer Load' Equal '15'")
                    font.pixelSize: 11
                    Layout.minimumWidth: rootRectangle.width
                    horizontalAlignment: Text.AlignHCenter
                    enabled: !model.busy
                }

                Shape {
                    height: 2
                    ShapePath {
                        strokeWidth: 1
                        strokeColor: "black"
                        strokeStyle: ShapePath.SolidLine
                        startX: 2; startY: 0
                        PathLine { x: controlItemsLayout.width - 2 ; y: 0 }
                    }
                }

                Text {
                    text: qsTr("New Barrier Condition:")
                    Layout.fillWidth: true
                }

                ComboBox {
                    id: networkAttributeComboBox
                    model: model.attributeListModel ? model.attributeListModel : null
                    Layout.fillWidth: true
                    enabled: !busyIndicator.visible

                    onModelChanged: currentIndex = 0;

                    onCurrentTextChanged: model.codedValueOrInputText(currentText);
                }

                ComboBox {
                    id: comparisonOperatorComboBox
                    model: comparisonOperatorModel
                    Layout.fillWidth: true
                    enabled: !busyIndicator.visible
                }

                RowLayout {
                    enabled: !model.busy
                    ComboBox {
                        id: valueSelectionComboBox
                        Layout.fillWidth: true
                        enabled: !busyIndicator.visible
                        visible: !model.textFieldVisible
                        model: model.valueSelectionListModel
                    }

                    TextField {
                        id: inputTextField
                        Layout.minimumHeight: valueSelectionComboBox.height
                        Layout.fillWidth: true
                        visible: model.textFieldVisible
                        validator: DoubleValidator {}
                        color: "black"
                        placeholderText: qsTr("Enter value here")
                        placeholderTextColor: "black"
                        selectByMouse: true
                        background: Rectangle {
                            anchors.centerIn: parent
                            height: parent.height
                            width: parent.width
                            color: "white"
                        }
                    }
                }

                Button {
                    text: qsTr("Add")
                    Layout.fillWidth: true
                    enabled: !busyIndicator.visible
                    onClicked: {
                        if (model.textFieldVisible) {
                            if (inputTextField.text)
                                model.addCondition(networkAttributeComboBox.currentText, comparisonOperatorComboBox.currentIndex, inputTextField.text);
                            return;
                        } else {
                            model.addCondition(networkAttributeComboBox.currentText, comparisonOperatorComboBox.currentIndex, valueSelectionComboBox.currentIndex);
                        }
                    }
                }

                ScrollView {
                    Layout.fillWidth: true
                    Layout.maximumWidth: rootRectangle.width
                    Layout.minimumHeight: 50
                    Layout.maximumHeight: .15 * rootRectangle.height
                    clip: true
                    Row {
                        anchors.fill: parent
                        Text {
                            text: model.expressionBuilder
                        }
                    }
                }

                RowLayout {
                    enabled: !model.busy
                    Button {
                        text: qsTr("Trace")
                        Layout.fillWidth: true
                        enabled: !busyIndicator.visible
                        onClicked: model.trace();
                    }

                    Button {
                        text: qsTr("Reset")
                        Layout.fillWidth: true
                        enabled: !busyIndicator.visible
                        onClicked: model.reset();
                    }
                }
            }
        }
    }

    Dialog {
        id: dialog
        modal: true
        standardButtons: Dialog.Ok
        x: (parent.width - width) / 2
        y: (parent.height - height) / 2

        Text {
            text: model.dialogText
            anchors.centerIn: parent
        }
    }

    BusyIndicator {
        id: busyIndicator
        anchors.centerIn: parent
        visible: model.busy
    }

    // Declare the C++ instance which creates the scene etc. and supply the view
    ConfigureSubnetworkTraceSample {
        id: model

        onShowDialog: dialog.open();
    }
}

Your browser is no longer supported. Please upgrade your browser for the best experience. See our browser deprecation post for more details.